Printing or Extracting Footnotes

Hillary works for an academic journal, and the citations contained in the footnotes of their articles need to be source-checked. She wonders if there is a way to print just the footnotes or, better still, copy the footnotes to a separate document.

This question is actually a bit trickier than it may, at first, seem. Let's start by looking at how to print just the footnotes, as that is arguably the easiest task to perform. The bottom line is that you cannot print just the footnotes. You can, however, print just the endnotes. Follow these steps:

1. Save your document.
2. Display the References tab of the ribbon.
3. Click the small icon at the bottom-right of the Footnotes group. Word displays the Footnote and Endnote dialog box. (See Figure 1.)



Figure 1. The Footnote and Endnote dialog box.

4. Click the Convert button. Word displays the Convert Notes dialog box. (See Figure 2.)



Figure 2. The Convert Notes dialog box.

5. Click the Convert All Footnotes to Endnotes radio button. (If you only have footnotes in your document, this is the only radio button available.)
6. Click the OK button. The Footnote and Endnote dialog box is again displayed.
7. Click the Endnotes radio button.
8. Using the Number Format drop-down list, choose Arabic numerals, the same as you would use for footnotes.
9. Click the Apply button. The dialog box is closed and all your footnotes are converted to endnotes with the proper numbering.
10. Press Ctrl+End. Word moves the insertion point to the end of the document, just before the beginning of the endnotes.
11. Press Ctrl+Enter. This inserts a page break, which means that the endnotes will start at the top of a new page.
12. Press Ctrl+P. Word displays the printing options.
13. Change the printing options to indicate you only want to print the pages from the current page (which is the first page of the endnotes) through the rest of the document.
14. Click Print.
15. Close the document without saving it.

You close the document without saving because you did step 1, which means you don't need to undo all the note changes you just did. You can then use your printout to do your source checking.

Sometimes, though, you want to get your footnotes into their own document, just as Hillary indicated. Here's a quick way to do it:

1. Open your document, the one with the footnotes.
2. Open a blank document.
3. In the original document, place the insertion point within a footnote. (It doesn't really matter which footnote.)
4. Press Ctrl+A. Word selects all the footnotes.
5. Press Ctrl+C. Word copies all the footnotes to the Clipboard.
6. Switch to the new, blank document.
7. Press Ctrl+V. Word pastes all the footnotes into the new document.

There is a huge drawback to doing these steps, though. You'll immediately notice that in the new document, the pasted footnotes all have the same number—they are all shown as footnote 1. This occurs regardless of how you select your footnotes, what view you are using in Word, or even if you convert to endnotes and copy and paste them. Once pasted in the new document, the numbering of the notes is ruined.

The only way around this that I've been able to discover is to follow the printing instructions provided earlier, but instead print to a PDF file. You can then load the PDF file back into Word, and you'll have your footnotes with the proper numbering in their own document.

If you need to export footnotes quite a bit, then the best solution may be a macro to do the work for you. Here is one that is quite handy:

Sub ExportFootnotes()
    Dim docSource As Document
    Dim docTarget As Document
    Dim fn As Footnote
    Dim r As Range

    Application.ScreenUpdating = False
    Set docSource = ActiveDocument

    ' Add new document and jump to end
    Set docTarget = Documents.Add
    Selection.EndKey wdStory

    For Each fn In docSource.Footnotes
        ' Work from a duplicate of the footnote so we can
        ' trim characters without touching the source
        Set r = fn.Range.Duplicate

        ' Remove any leading tabs, spaces, or non-breaking spaces
        If r.Characters.Count > 0 Then
            Do While r.Start < r.End _
                And (r.Characters.First.Text = vbTab _
                Or r.Characters.First.Text = " " _
                Or AscW(r.Characters.First.Text) = 160)
                r.MoveStart wdCharacter, 1
            Loop
        End If

        ' Copy the body of the footnote
        r.Copy

        ' Type the number, then paste the footnote
        Selection.TypeText CStr(fn.Index) & vbTab

        On Error Resume Next
        Selection.PasteSpecial DataType:=wdPasteRTF
        If Err.Number <> 0 Then
            Err.Clear
            Selection.Paste ' Fallback if PasteSpecial is unavailable
        End If
        On Error GoTo 0

        ' Ensure each entry ends with a paragraph mark
        Selection.TypeParagraph
    Next fn

    Application.ScreenUpdating = True
End Sub

The macro creates a brand new document and then copies each footnote to that document, making sure that the proper footnote number is used.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13953) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.