Deleting All Fields

When you are working with documents—particularly long documents created by someone else—you may have a need to delete all the fields in the document. The answer to how you do this depends almost entirely on what you mean by "deleting" a field.

If you mean that you want to get rid of the fields and replace them with plain text that represents the result of the field, then the easiest method is to select the entire document (Ctrl+A) and then press Ctrl+Shift+F9 to "unlink" the fields. Everyplace there was a field, the field is deleted and replaced with the result of the field.

If you simply want to get rid of all the fields and don't care that they be replaced with anything, you can use the Find and Replace capabilities of Word. Follow these steps:

1. Press Alt+F9. This makes all the field codes in your document visible, instead of the results of those fields.
2. Press Ctrl+H. Word displays the Replace tab of the Find and Replace dialog box. (See Figure 1.)



Figure 1. The Replace tab of the Find and Replace dialog box.

3. In the Find What box, enter ^d as what you are searching for (make sure you use a lowercase d). This is the code that Word understands as "any field."
4. Make sure the Replace With box is empty.
5. Click on Replace All.

All the fields in your document should now be gone. If you have to get rid of fields in this way quite often, it makes sense to create a macro that will handle the task for you. The following is a simple, short macro that goes through all the parts of your document and removes all the fields.

Sub DeleteFields()
    Dim rng As Range

    For Each rng In ActiveDocument.StoryRanges
        With rng.Fields
            While .Count > 0
                .Item(1).Delete
            Wend
        End With
    Next
End Sub

You can, of course, assign the macro to the Quick Access Toolbar or a shortcut key so it can be called into action as quickly as possible.

It should be noted that if your document has multiple text boxes, this macro will only remove the fields from the main document and the first text box. (Don't ask why; it seems to be quirk in Word.) If you have fields in more than just the first text box, then you'll need a different macro approach:

Sub DeleteAllFields()
    Dim rng As Range
    Dim shp As Shape
    Dim TxtFrame As TextFrame

    For Each rng In ActiveDocument.StoryRanges
        With rng.Fields
            While .Count > 0
                .Item(1).Delete
            Wend
        End With

        For Each shp In rng.ShapeRange
            Set TxtFrame = shp.TextFrame
            If Not TxtFrame Is Nothing Then
                If TxtFrame.HasText Then
                    With TxtFrame.TextRange.Fields
                        While .Count > 0
                            .Item(1).Delete
                        Wend
                    End With
                End If
            End If
        Next shp
    Next rng
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10818) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Deleting All Fields.