Combining Footnotes

Daniel has an academic paper that uses many footnotes. Right now, he has footnotes at the end of each sentence. He would like to combine all of the footnotes within a paragraph into a single footnote at the end of the paragraph. He wonders if there is a way to do this automatically.

There is no way to do this automatically, but you can do it with a macro. All the macro needs to do is to step through each paragraph in the document and see if it has any footnotes. Then, assuming it does, it concatenates those, deletes the footnotes, and adds a new footnote with the concatenated text at the end of the paragraph. Here's a macro that does just that:

Sub MoveFootnotes()
    Dim p As Paragraph
    Dim iFN As Integer
    Dim J As Integer
    Dim oCurPar As Object
    Dim sTemp As String

    For Each p In ActiveDocument.Paragraphs
        sTemp = ""
        iFN = p.Range.Footnotes.Count
        For J = iFN To 1 Step -1
            sTemp = p.Range.Footnotes(J).Range.Text & " " & sTemp
            p.Range.Footnotes(J).Delete
        Next J
        sTemp = Trim(sTemp)
        If sTemp > "" Then
            Set oCurPar = p.Range
            oCurPar.Collapse Direction:=wdCollapseEnd
            oCurPar.MoveEnd Unit:=wdCharacter, Count:=-1
            ActiveDocument.Footnotes.Add Range:=oCurPar, Text:=sTemp
        End If
    Next p
End Sub

Note that the macro concatenates the footnote text for each paragraph into the sTemp string. This is then used when adding the footnote to the end of the paragraph. This does present a drawback to the macro—it copies only text, not any formatting for the text.

For instance, if you have a bunch of footnotes that include citations to books, chances are good that those book titles are formatted in italic. After running the macro, the italic will be gone, though all the text is there. (There is no way that I'm aware of to transfer the formatting, intact, into the new footnote.)

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13767) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365.