Searching with a Different Search Engine

When working in a document, Lewis can select a word or phrase, right-click on it, and choose the "Search with Bing" option. He's not happy with Bing's search results and would much prefer to search with a different search engine, such as Google. Lewis wonders if there is a way to add other search engines to the right-click menu or, perhaps, change the "Search with Bing" option to use a different search engine.

The very fact that Lewis has a "Search with Bing" option on the right-click Context menu tells me that he is using either Word 2010 or Word 2013. This particular option doesn't exist in either Word 2007 or Word 2016 or a later version.

In both Word 2010 and Word 2013 you can edit the Windows Registry to modify the "Search with Bing" option. Editing the Registry should be done carefully, as one misstep could result in an unusable system. (If you need a refresher on how to edit the Registry, including how to start the Registry Editor, see this tip on the WindowsTips site.) Follow these steps to make the modification:

1. Exit Word.
2. Start the Registry editor.
3. Locate and select the following data key. (This data key, as shown below, is for Word 2013. If you are using Word 2010, change 15.0 to 14.0.)

     HKEY_CURRENT_USER\Software\Microsoft\Office\15.0\Word\Data

4. Choose Edit | New | String Value. The Registry Editor adds a new string value to the right side of the Registry and allows you to immediately enter its name.
5. Name the new string value "SearchProviderName" (without the quotes).
6. Right-click on the newly added string value and choose Modify from the resulting Context menu. The Registry Editor displays the Edit String dialog box.
7. In the Value Data field enter "Google" (without the quotes.)
8. Click OK. The information in the Registry Editor is updated.
9. Again choose Edit | New | String Value. The Registry Editor adds another new string value to the right side of the Registry and you can, again, change its name.
10. Name the new string value "SearchProviderURI" (without the quotes).
11. Right-click on the newly added string value and choose Modify from the resulting Context menu. The Registry Editor displays the Edit String dialog box.
12. 12. In the Value Data field enter "https://www.google.com/search?q=" (again, without the quotes).
13. Click OK. The information in the Registry Editor is updated.
14. Close the Registry editor.
15. Restart Word.

Now, go ahead and select some text. When you right-click on it, the Context menu option has changed from "Search with Bing" to "Search with Google." If, at some point (and for some reason) you want to stop using Google and again start using Bing, just delete the two Registry entries you created in these steps.

The foregoing Registry modification won't work in Word 2007 or Word 2016 or a later version. As already mentioned, neither of these versions include the "Search with Bing" option. (Word 2016 and later versions includes a "Smart Lookup" option, but no "Search with Bing" option.) The only way that we've been able to find to add a "Search with Google" option to the Context menu is to add some rather hefty macros to your document. The following, for instance, is a set of macros that will add the option on a Word 2007 system. These should be added to a regular VBA module:

Option Explicit
Dim oPopUp As CommandBarPopup
Dim oCtr As CommandBarControl
Private pWebAddress As String
Public Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, _
  ByVal lpOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub BuildControls()
    Dim oBtn As CommandBarButton
    'Make changes to the Add-In template
    CustomizationContext = ThisDocument.AttachedTemplate
    'Prevent double customization
    Set oPopUp = CommandBars.FindControl(Tag:="custPopup")
    If Not oPopUp Is Nothing Then GoTo Add_Individual
    'Add PopUp menu control to the top of the "Text" short-cut menu
    Set oPopUp = CommandBars("Text").Controls.Add(msoControlPopup, , , 1)
    With oPopUp
        .Caption = "Search With Google"
        .Tag = "custPopup"
        .BeginGroup = True
    End With
    Set oBtn = oPopUp.Controls.Add(msoControlButton)
    With oBtn
        .Caption = "Google"
        .FaceId = 940
        .Style = msoButtonIconAndCaption
        .OnAction = "WebPage"
    End With
    Set oBtn = Nothing
Add_Individual:
    'Or add individual commands directly to menu
    Set oBtn = CommandBars.FindControl(Tag:="custCmdBtn")
    If Not oBtn Is Nothing Then Exit Sub
    'Add control using built-in ID 758 (Boo&kmarks...)
    Set oBtn = Application.CommandBars("Text").Controls.Add(msoControlButton, 758, , 2)
    oBtn.Tag = "custCmdBtn"
    If MsgBox("This action caused a change to your Add-In template." _
      & vbCr + vbCr & "Recommend you save those changes now.", _
      vbInformation + vbOKCancel, "Save Changes") = vbOK Then
          ThisDocument.Save
    End If
    Set oPopUp = Nothing
    Set oBtn = Nothing
lbl_Exit:
    Exit Sub
End Sub

Sub RemoveContextMenuItem ()
    'Make command bar changes in Add-In template
    CustomizationContext = ThisDocument.AttachedTemplate
    On Error GoTo Err_Handler
    Set oPopUp = CommandBars("Text").Controls("Search With Google")
    'Delete individual commands on the PopUp menu.
    For Each oCtr In oPopUp.Controls
        oCtr.Delete
    Next
    'Delete the PopUp itself.
    oPopUp.Delete
    'Delete individual custom commands on the Text menu.
Reenter:
    For Each oCtr In Application.CommandBars("Text").Controls
        If oCtr.Caption = "Boo&kmark..." Then
            oCtr.Delete
            Exit For
        End If
    Next oCtr
    If MsgBox("This action caused a change to your Add-In template." _
      & vbCr + vbCr & "Recommend you save those changes now.", _
      vbInformation + vbOKCancel, "Save Changes") = vbOK Then
        ThisDocument.Save
    End If
    Set oPopUp = Nothing
    Set oCtr = Nothing
    Exit Sub
Err_Handler:
    ' MsgBox Err.Number
    Resume Reenter
End Sub
Public Sub WebPage()
    pWebAddress = "https://www.google.com/search?q=" & Selection.Text
    Call NewShell(pWebAddress, 3)
End Sub
Public Sub NewShell(cmdLine As String, lngWindowHndl As Long)
    ShellExecute lngWindowHndl, "open", cmdLine, _
      Selection.Text, Selection.Text, 1
End Sub

In order to add the "Search with Google" option to the Context menu, simply run the BuildControls macro. If you later want to remove the option, you can run the RemoveContextMenuItem macro.

These macros are based on work done by Greg Maxey at his website, here:

https://gregmaxey.com/word_tip_pages/customize_shortcut_menu.html

As mentioned, the macros will work only on a Word 2007 system. For reasons that Greg discusses on his website, they will not work on Word 2016 or later systems without some rather major modifications, and they may not be stable even after the modifications because of changes that Microsoft continues to make.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (166) applies to Microsoft Word 2007, 2010, 2013, 2019, and Word in Microsoft 365.