Replacing the Last Comma

Rebecca is looking for a way to replace the last comma in a sentence with the word "and." She apparently needs to perform this type of edit quite a bit, and thought there might be a quick and easy way to doing the edit rather than needing to manually do it.

There is no built-in way to do this specific edit in Word, but you can create a simple macro that will search for the last comma, delete it, and then type the desired word. The following is an example of such a macro.

Sub ReplaceLastComma()
    Dim rSentence As Range
    Dim rComma As Range
    Dim rCheck As Range
    Dim re As Object
    Dim J As Long
    Dim sRaw As String
    Dim sAfter As String

    ' Set to True if you want the last comma to remain
    ' Set to False if you want the last comma deleted
    Const bOxford As Boolean = True

    Set re = CreateObject("VBScript.RegExp")
    re.Pattern = "^\s*and\b"
    re.IgnoreCase = True
    re.Global = False

    For Each rSentence In Selection.Sentences
        sRaw = rSentence.Text
        For J = Len(sRaw) To 1 Step -1
            If Mid(sRaw, J, 1) = "," Then
                Set rComma = rSentence.Duplicate
                rComma.Start = rSentence.Start + J - 1
                rComma.End = rComma.Start + 1

                Set rCheck = rSentence.Duplicate
                rCheck.Start = rComma.End
                rCheck.End = rSentence.End

                sAfter = rCheck.Text

                If re.Test(sAfter) Then
                    If Not bOxford Then rComma.Delete
                Else
                    If bOxford Then
                        rComma.Text = ", and"
                    Else
                        rComma.Text = " and"
                    End If
                End If
                Exit For
            End If
        Next J
    Next rSentence
End Sub

The macro steps through each sentence in whatever text you've selected in the document. The macro steps backwards through the text of each sentence. (The text is assigned to the variable sRaw for ease of processing.) If a comma is found, then the text is checked to see if it is followed by the word "and" already. If so, then the comma is deleted based on the setting of the bOxford constant. (The purpose of the constant is to specify if you want to include an Oxford comma or not.) The word "and" is also added, if it doesn't already exist.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (12378) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Replacing the Last Comma.