Default Envelope Margins

Word does not allow you to easily change the default positions at which the return address and main address are printed on an envelope. There are several ways around this problem, each of which exemplifies the flexible nature of Word to accomplish a task.

It seems that envelope settings are stored as a part of your document, and therefore can be stored in a template. If you only print one size of envelope, the easiest way to change the default printing position for your envelopes is to follow these steps:

1. Load the Normal template. (This is the default template used by Word whenever you create a blank document.)
2. Display the Mailings tab of the ribbon.
3. Click the Envelopes tool, in the Create group. Word displays the Envelopes and Labels dialog box, with the Envelopes tab selected. (See Figure 1.)



Figure 1. The Envelopes tab of the Envelopes and Labels dialog box.

4. Click on the Options button. Word displays the Envelope Options dialog box.
5. Make sure the Envelope Options tab is selected. (See Figure 2.)



Figure 2. The Envelope Options dialog box.

6. In the appropriate fields, change the positioning of the addresses, as desired.
7. Click on OK to close the Envelope Options dialog box.
8. Click on Add to Document. This inserts an envelope in your template (which you have open, remember?).
9. Choose Select All from the Edit menu. This selects all the envelope information that was just added to your document by Word.
10. Press the Del key. The envelope is removed from your document.
11. Save the template by clicking on the Save tool or by choosing Save from the File menu.
12. Close the template.

Now, the next time you use a document based on the Normal style, the envelope settings will reflect those you created in these steps.

You can also use a solution that uses a macro to create your envelopes. For instance, you can start with a new, blank document, and create an envelope that is just the way you want it to be. Add this envelope to the blank document, and then save it as a template using a descriptive name (such as Envelope.dot). Then, create the following macro and assign it to the Quick Access Toolbar:

Sub DoEnv()
    Documents.Add Template:="Envelope", NewTemplate:=False
    Selection.EndKey Unit:=wdStory
    Selection.MoveLeft Unit:=wdCharacter, Count:=2
    Selection.PasteSpecial DataType:=wdPasteText
    Application.PrintOut Range:=wdPrintCurrentPage
    ActiveWindow.Close (False)
End Sub

To print an envelope, highlight the address in a letter then click on the Quick Access Toolbar button with which this macro is associated. The macro copies the address to the Clipboard, pastes it at the proper place in a new document based on the Envelope template, prints the envelope, and then closes the envelope document without saving it.

A different approach is to use a macro to set the standard (meaning, those you want to use most often) envelope settings for you. The following macro will do just that:

Sub ToolsEnvelopesAndLabels()
    Dim EnvThere As Integer
    Dim recipient As String
    EnvThere = False
    recipient = Selection.Text
    On Error Resume Next
    If IsError(ActiveDocument.Envelope.Address) Then
        ActiveDocument.Envelope.Insert
        EnvThere = True
    End If
    With ActiveDocument.Envelope
        .DefaultFaceUp = True
        .DefaultOrientation = wdCenterClockwise
        .DefaultHeight = CentimetersToPoints(11)
        .DefaultWidth = CentimetersToPoints(22)
        .AddressFromLeft = CentimetersToPoints(5)
        .AddressFromTop = CentimetersToPoints(5)
        .ReturnAddressFromLeft = CentimetersToPoints(2)
        .ReturnAddressFromTop = CentimetersToPoints(2)
    End With
    If EnvThere Then
        ActiveDocument.Sections(1).Range.Delete
    Else
        ActiveDocument.Envelope.UpdateDocument
    End If
    With Application.Dialogs(wdDialogToolsCreateEnvelope)
        .ExtractAddress = True
        If .AddrText = "" Then
            .AddrText = recipient
        End If
        .Show
    End With
End Sub

To use this macro, first select the address you want used on the envelope. The macro grabs the current selection and uses it as the envelope address if no other address has already been defined. Next the IsError function determines if an envelope already exists; if one doesn't, a new one is inserted and EnvThere is set to tell us to delete it once we have changed the default properties. Once an envelope exists in the document we then change the default properties of the envelope. This is done in the With ActiveDocument.Envelope section. You can customize these properties as needed or simply omit them. (This example uses the CentimetersToPoints function to set the values; you could use other functions such as InchesToPoints, if desired.) The macro ends up by displaying the Envelope and Labels dialog box so you can make any last minute changes before printing or creating your envelope.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (11433) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Default Envelope Margins.