Only Showing Readability Statistics

When you do a grammar check on your document, the very last step performed by Word is to display a set of readability statistics that you can use to analyze the presentation of your content. There may be times when you want to only display the readability statistics, without going through the complete grammar check first. Unfortunately, Word does not provide a way to do this. You can, however, create a macro that will display the readability statistics quite nicely. The heart of such a macro would be the ReadabilityStatistics collection.

To get an idea how such a macro could be written, consider the following single-line macro:

Sub CheckTest()
    MsgBox ActiveDocument.Content.ReadabilityStatistics(8).Value
End Sub

This macro displays a number that represents the Flesch Reading Ease value, which (as of this writing) is the eighth member of the ReadabilityStatistics collection. There are 10 individual elements in the collection, as follows:

Again, these index values are as of this writing. Microsoft has changed the order of the statistics in the past, and may do so in the future.

To display all ten statistics (as would be done in a complete grammar check of your document), all you need to do is have your macro step through the various members of the collection and display their values. The following macro does just that:

Sub Readability1()
    Dim DocStats As String
    Dim MBTitle As String
    Dim J As Integer

    MBTitle = "Readability Statistics"
    DocStats = ""
    With ActiveDocument.Content
        For J = 1 to 10
            DocStats = DocStats & .ReadabilityStatistics(J) & ": "
            DocStats = DocStats & .ReadabilityStatistics(J).Value
            DocStats = DocStats & vbCrLf
        Next J
    End With
    MsgBox DocStats, vbOKOnly, MBTitle
End Sub

When you run the macro, understand that it takes a bit of time to run because the entire content of your document is evaluated 10 times over. Depending on the speed of your system, the length of your document, and its complexity, it can take quite a bit of time to run. Be patient; once the ten statistics are completed, they are displayed on the screen.

If you prefer to have the tests run on a selection of text (instead of on the entire document), then you could modify the macro to affect whatever text is selected, in this manner:

Sub Readability2()
    Dim DocStats As String
    Dim MBTitle As String
    Dim J As Integer

    MBTitle = "Readability Statistics"

    If Selection.Type = wdSelectionIP Then
        DocStats = "No text was selected. You must make a selection "
        DocStats = DocStats & "before running this macro."
    Else
        DocStats = "These are the readability statistics for the "
        DocStats = DocStats & "selected portion of the document."
        DocStats = DocStats & vbCrLf & vbCrLf
        With Selection.Range
            For J = 1 to 10
                DocStats = DocStats & .ReadabilityStatistics(J) & ": "
                DocStats = DocStats & .ReadabilityStatistics(J).Value
                DocStats = DocStats & vbCrLf
            Next J
        End With
    End If
    MsgBox DocStats, vbOKOnly, MBTitle
End Sub

These macros could obviously be modified to perform a subset of the available tests, returning only the data in which you are interested.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10666) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Only Showing Readability Statistics.