An Automatic File Name

One of the properties that Word allows you to save with a document is a title for the document. If you use this property regularly with your new documents, you can create a way for Word to automatically name your document by looking at the title you provided.

This particular macro is well suited for use with letters, although it could be easily modified for other types of documents. The macro is named FileSaveAs, so it replaces the built-in Save As command. The best place to save this macro is in the template you use for your letters:

Sub FileSaveAs()
    Dim MyDocTitle As String
    MyDocTitle = Format(Date, "yymmdd") + " letter"

    Selection.HomeKey Unit:=wdStory
    Selection.Find.ClearFormatting
    With Selection.Find
        .Text = "^pDear "
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute

    If Selection.Find.Found Then
        Selection.MoveRight Unit:=wdCharacter, Count:=1
        Selection.EndKey Unit:=wdLine, Extend:=wdExtend
        Selection.MoveLeft Unit:=wdCharacter, Count:=2, Extend:=wdExtend
        If Len(Selection.Text) > 1 Then
            MyDocTitle = MyDocTitle + " to " + Selection.Text
        End If
    End If

    With Dialogs(wdDialogFileSummaryInfo)
        .Title = MyDocTitle
        .Execute
    End With

    Dialogs(wdDialogFileSaveAs).Show
End Sub

The macro sets the file name, initially, to today's date, along with the word "letter." It then searches through the document for the word "Dear" beginning at the start of a paragraph. If it finds it, then it grabs the text after "Dear" and appends that to the filename. If you don't start your letters with something like "Dear Frank" or "Dear Tanya Garrison," then you'll want to modify what is searched for in the macro.

Note that this macro only works properly when you are first saving a new document. If you use it with an existing document (one previously saved under a different name), the original name is still suggested as the default in the Save As dialog box, even though the document title is modified.

The macro can be assigned to the Quick Access Toolbar or a shortcut key so you can save your documents and name them automatically.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10358) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: An Automatic File Name.