Hyperlinks from Headings to the TOC

Peter writes manuals and can autogenerate a chapter's Table of Contents in the normal way. This allows readers to click on a TOC entry and jump to the heading, but there is no way to click on the heading and get back to the TOC. So readers can do this, Peter has to individually apply a hyperlink to the heading and then get rid of the underlining, which he finds unsightly. A manual's chapter can contain hundreds of headings, so the task of applying the hyperlinks individually can be painful. Peter wonders if there is a way to automate the adding of hyperlinks to headings as he needs.

Peter's approach, while well intentioned, is completely unnecessary. Word does provide a way to click a heading in the TOC (which Peter knows) and then return to that heading in the TOC (which Peter apparently doesn't know). The specific shortcut for accomplishing this task is Alt+Left Arrow. The shortcut jumps back to where you were before clicking on the hyperlink in the TOC, which makes it great for long tables of contents—you are returned to exactly where you were rather than to the beginning of the TOC.

The shortcut key is the best solution for readers; it works by default on a standard Word installation. If wanted, however, you could add a Back button to your Quick Access Toolbar that could be clicked to return to the TOC's point of departure. Follow these steps:

1. Display the Word Options dialog box. (In Word 2007 click the Office button and then click Word Options. In Word 2010 or a later version, display the File tab of the ribbon and then click Options.)
2. At the left side of the dialog box click Customize (Word 2007) or Quick Access Toolbar (later versions of Word). (See Figure 1.)



Figure 1. The Quick Access Toolbar area of the Word Options dialog box.

3. Using the Choose Commands From drop-down list, choose All Commands.
4. In the list of commands, locate and select the Back command.
5. Click the Add button. The Back command now appears at the right side of the dialog box, in the list of Quick Access Toolbar commands.
6. Use the Up and Down arrow buttons to situate the Back command within the Quick Access Toolbar commands.
7. Click OK.

The Back command, which now appears on the Quick Access Toolbar, performs the exact same function as the Alt+Left Arrow shortcut.

If you still want to add hyperlinks to headings, the only way to automate the process is to use a macro. The following macro steps through each entry in the first TOC in the document, finds the referenced heading in the main body of the text, and then adds a hyperlink back to the TOC.

Sub HyperlinkHeadings()
    Dim hyp As Hyperlink
    Dim toc As TableOfContents
    Dim k As Long
    Dim bkmk As String
    Dim sCode As String
    Dim fld As Field
    Dim aRange As Range

    If ActiveDocument.TablesOfContents.Count = 0 Then
        MsgBox "There are no Tables of Contents in document"
        Exit Sub
    End If

    Set toc = ActiveDocument.TablesOfContents(1)

    For Each fld In toc.Range.Fields
        sCode = fld.Code.Text
        If InStr(sCode, "HYPERLINK") > 0 Then
            bkmk = Mid(sCode, InStr(sCode, "_"))
            bkmk = Left(bkmk, Len(bkmk) - 2)
            fld.Select
            ActiveDocument.Bookmarks.Add Range:=Selection.Range, _
              Name:=bkmk & "R"

            Set aRange = ActiveDocument.Bookmarks(bkmk).Range
            aRange.Select
            With ActiveDocument.Hyperlinks.Add(Anchor:=Selection.Range, _
                Address:="", SubAddress:=bkmk & "R", _
                  TextToDisplay:=Selection.Text)
                .Range.Select
                Selection.ClearCharacterAllFormatting
            End With
        End If
    Next fld

    Options.CtrlClickHyperlinkToOpen = False
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13059) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021.