Copying a Range of Pages in a Macro

Kevin wonders if there is a way, in VBA, to copy a range of pages. He knows how to copy paragraphs and a contiguous range of text, but he doesn't know how to copy entire pages.

There is no VBA object that references an entire page, such as there is with a paragraph, nor is there a VBA statement that will allow you to select a page. You can, however, calculate what would comprise a page and then select that range. The general concept is shown in this macro:

Sub CopyPages1()
    Dim rCopy As Range

    Set rCopy = ActiveDocument.GoTo(What:=wdGoToPage, _
      Which:=wdGoToAbsolute, Count:=7)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=9

    rCopy.End = Selection.Bookmarks("\Page").Range.End

    rCopy.Select
End Sub

This macro sets the rCopy range equal to the point where page 7 begins. It then selects the text at the very beginning of page 9 and uses one of Word's built-in bookmarks to select from the top of page 7 to the end of page 9. (That is what this macro is designed to do—select pages 7 through 9.)

You should note, however, that pages are very fluid in Word. If you use the exact same document on two different systems, the above macro may very well return different selections entirely. Why? Because the pages can flow differently on each of the systems.

If you want to actually copy the selected pages (7 through 9), then you can modify the macro just a bit to get the desired result.

Sub CopyPages2()
    Dim rCopy As Range
    Dim rCurrent As Range

    Set rCurrent = Selection.Range

    Set rCopy = ActiveDocument.GoTo(What:=wdGoToPage, _
      Which:=wdGoToAbsolute, Count:=7)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=9

    rCopy.End = Selection.Bookmarks("\Page").Range.End
    rCopy.Copy
    Documents.Add
    ActiveDocument.Range.PasteSpecial

    rCurrent.Select
End Sub

Note that the macro "remembers" what the user had selected before it was run, storing the range in the rCurrent variable and using it to again select that area at the end of the macro. The selected pages (again, 7 through 9) are copied to a brand new document.

You should note that the above macros only work properly if there are actually at least 9 pages in the current document. If you would like a more flexible and robust macro, you might consider the following variation.

Sub CopyPages3()
    Dim rCopy As Range
    Dim rCurrent As Range
    Dim sTemp As String
    Dim i As Integer
    Dim iStart As Integer
    Dim iEnd As Integer
    
    Set rCurrent = Selection.Range

    ' Get page numbers to be copied
    sTemp = InputBox("Page range to copy (use format 6-7)", "")
    i = InStr(sTemp, "-")
    If i > 0 Then
        iStart = Val(Left(sTemp, i - 1))
        iEnd = Val(Mid(sTemp, i + 1))
        
        If iStart < 1 Then iStart = 1
        If iEnd < iStart Then iEnd = iStart
        With ActiveDocument.Range
            If iStart > .Information(wdNumberOfPagesInDocument) Then
                iStart = .Information(wdNumberOfPagesInDocument)
            End If
            If iEnd > .Information(wdNumberOfPagesInDocument) Then
                iEnd = .Information(wdNumberOfPagesInDocument)
            End If
        End With

        ' Set the range
        Set rCopy = ActiveDocument.GoTo(What:=wdGoToPage, _
          Which:=wdGoToAbsolute, Count:=iStart)
        
        Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, _
          Count:=iEnd
        rCopy.End = Selection.Bookmarks("\Page").Range.End
        
        ' Copy range to a new document
        rCopy.Copy
        Documents.Add
        ActiveDocument.Range.PasteSpecial

        rCurrent.Select
    Else
        If sTemp > "" Then
            MsgBox "There is no dash character"
        End If
    End If
End Sub

This version asks the user to specify a page range to be copied. The page numbers are adjusted to make sure that the starting number is less than or equal to the ending number, and both starting and ending numbers are ensured to be less than the total number of pages in the document.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (5295) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.