Printing a Font List

In older versions of Word (much older, as in Word for Windows 2), there was a feature that allowed you to quickly print a list of fonts on your system. Unfortunately, that is no longer the case. You can, however, rather easily create a macro that can put such a list together for you:

Sub ListFontNames()
    Dim J As Integer
    Dim NewDoc As Document

    ' Create a new document
    Set NewDoc = Documents.Add

    ' Add font names to document
    For J = 1 To FontNames.Count
        Selection.TypeText (FontNames(J))
        Selection.TypeParagraph
    Next J
End Sub

The macro creates a new document and then simply steps through the FontNames collection and adds each of the names to the document. The speed at which the macro works depends on how many fonts you have installed on your system.

If you want something a bit more elaborate, you could use the following macro. It creates a document, but then puts all the font names into a table. In the second column of the table, it provides a formatted sample of the font.

Sub FontExamples()
    Dim J As Integer
    Dim F As Integer
    Dim sTemp As String
    Dim sTest As String
    Dim Continue As Integer
    Dim rng As Range
    Dim FontTable As Table
    Dim NewDoc As Document

    ' Specify the sample text for second column
    sTest = "ABCDEFG abcdefg 1234567890"

    ' Check to see if the user wants to proceed
    F = FontNames.Count
    sTemp = "There are " & F & " fonts on this system."
    sTemp = sTemp & "Building the document may take quite a while."
    sTemp = sTemp & "Do you want to continue?"
    Continue = MsgBox(sTemp, vbYesNo, "Build Font List")

    If Continue = vbYes Then
        ' Put together a string that contains the table contents
        sTemp = "Font Name" & vbTab & "Font Example"
        For J = 1 To F
            sTemp = sTemp & vbCr & FontNames(J) & vbTab & sTest
        Next J

        ' Create a new document
        Set NewDoc = Documents.Add

        ' Add string contents and convert to table
        Set rng = Selection.Range
        rng.Text = sTemp
        Set FontTable = rng.ConvertToTable(Separator:=vbTab, _
          AutoFitBehavior:=wdAutoFitFixed)

        ' Set general table properties
        With FontTable
            .Borders.Enable = False
            .Range.Font.Name = "Arial"
            .Range.Font.Size = 10
            .Rows(1).Range.Font.Bold = True
            .Rows(1).Range.Font.Size = 12
        End With

        ' Go through the sample cells and format them
        For J = 1 To F
            FontTable.Cell(J + 1, 2).Range.Font.Name = FontNames(J)
        Next J

        ' Sort the table
        FontTable.Sort SortOrder:=wdSortOrderAscending
    End If
End Sub

This macro does quite a bit more than the previous one. The table itself is created rather quickly, but it can take a great deal of time to step through each of the sample cells and format it using the appropriate font. This is why the macro lets you know how many fonts are on your system before proceeding.

Regardless of which macro you choose to use, you end up with a complete font list for your system. You can then print it out and keep it handy when you are working with Word.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (4358) applies to Microsoft Word 2007, 2010, 2013, and 2016. You can find a version of this tip for the older menu interface of Word here: Printing a Font List.