Please Note: This article is written for users of the following Microsoft Word versions: 2007, 2010, 2013, and 2016. If you are using an earlier version (Word 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Word, click here: Printing a Font List.

Printing a Font List

by Allen Wyatt
(last updated September 9, 2017)

4

In older versions of Word (much older, as in Word for Windows 2), there was a feature that allowed you to quickly print a list of fonts on your system. Unfortunately, that is no longer the case. You can, however, rather easily create a macro that can put such a list together for you:

Sub ListFontNames()
    Dim J As Integer
    Dim NewDoc As Document

    ' Create a new document
    Set NewDoc = Documents.Add

    ' Add font names to document
    For J = 1 To FontNames.Count
        Selection.TypeText (FontNames(J))
        Selection.TypeParagraph
    Next J
End Sub

The macro creates a new document and then simply steps through the FontNames collection and adds each of the names to the document. The speed at which the macro works depends on how many fonts you have installed on your system.

If you want something a bit more elaborate, you could use the following macro. It creates a document, but then puts all the font names into a table. In the second column of the table, it provides a formatted sample of the font.

Sub FontExamples()
    Dim J As Integer
    Dim F As Integer
    Dim sTemp As String
    Dim sTest As String
    Dim Continue As Integer
    Dim rng As Range
    Dim FontTable As Table
    Dim NewDoc As Document

    ' Specify the sample text for second column
    sTest = "ABCDEFG abcdefg 1234567890"

    ' Check to see if the user wants to proceed
    F = FontNames.Count
    sTemp = "There are " & F & " fonts on this system."
    sTemp = sTemp & "Building the document may take quite a while."
    sTemp = sTemp & "Do you want to continue?"
    Continue = MsgBox(sTemp, vbYesNo, "Build Font List")

    If Continue = vbYes Then
        ' Put together a string that contains the table contents
        sTemp = "Font Name" & vbTab & "Font Example"
        For J = 1 To F
            sTemp = sTemp & vbCr & FontNames(J) & vbTab & sTest
        Next J

        ' Create a new document
        Set NewDoc = Documents.Add

        ' Add string contents and convert to table
        Set rng = Selection.Range
        rng.Text = sTemp
        Set FontTable = rng.ConvertToTable(Separator:=vbTab, _
          AutoFitBehavior:=wdAutoFitFixed)

        ' Set general table properties
        With FontTable
            .Borders.Enable = False
            .Range.Font.Name = "Arial"
            .Range.Font.Size = 10
            .Rows(1).Range.Font.Bold = True
            .Rows(1).Range.Font.Size = 12
        End With

        ' Go through the sample cells and format them
        For J = 1 To F
            FontTable.Cell(J + 1, 2).Range.Font.Name = FontNames(J)
        Next J

        ' Sort the table
        FontTable.Sort SortOrder:=wdSortOrderAscending
    End If
End Sub

This macro does quite a bit more than the previous one. The table itself is created rather quickly, but it can take a great deal of time to step through each of the sample cells and format it using the appropriate font. This is why the macro lets you know how many fonts are on your system before proceeding.

Regardless of which macro you choose to use, you end up with a complete font list for your system. You can then print it out and keep it handy when you are working with Word.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the WordTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (4358) applies to Microsoft Word 2007, 2010, 2013, and 2016. You can find a version of this tip for the older menu interface of Word here: Printing a Font List.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Setting Tab Stops Using the Tabs Dialog Box

Aligning different lines in your document is easy. Using the tab stops feature in Word, you can set four different types ...

Discover More

Underlining Tabs In Numbered Lists

When Word creates an automatically numbered list, it removes some of your formatting flexibility. One thing you can't ...

Discover More

Quickly Dumping Array Contents

Variable arrays are used quite often in macros. If you use an array once in your macro and then need to reuse it for ...

Discover More

Comprehensive VBA Guide Visual Basic for Applications (VBA) is the language used for writing macros in all Office programs. This complete guide shows both professionals and novices how to master VBA in order to customize the entire Office suite for their needs. Check out Mastering VBA for Office 2010 today!

More WordTips (ribbon)

Printing Custom Properties

Do you use custom document properties? They can be very helpful, but sometimes hard to get at. This tip shows a way you ...

Discover More

Printing without Headings

One way to use heading styles is to create a story outline. When it comes time to print the story, though, you may not ...

Discover More

Controlling the Printing of Highlighting

Using Word's built-in highlighter tool can be a great way to add markup to a document and attract a reader's eyes to ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 9 - 6?

2017-09-13 11:26:45

Allen

Jackie,

At the right side of this page (well, at the right side of ANY page) is a link that says "WordTips FAQ." Click on that link and you'll see a series of common questions and answers. One of those questions is "How Can I Use the Macros In WordTips?" The answer may be helpful in regard to your question here.

-Allen


2017-09-13 10:29:49

Jackie Oliveira

Hi Allen - When you give an example for a macro such as create a Font List, if you're not familiar with making macros how do you input your instructions? I guess you just don't copy and paste, that step by step information needs to be input but I can never make your macros work. Any guidance would be appreciated.

Thank you.
Jackie Oliveira


2017-09-10 13:24:27

Ted Duke

I have been a long-time user of the app Printer's Apprentice from http://www.loseyourmind.com/default.aspx --- I am just a customer, not affiliated with that site. I have a large collection of fonts from various web sites in addition to the increasing number of fonts that Microsoft Word brings every year.


2017-09-09 12:55:05

Mitchell Sackson

Many moons ago, I had a routine that sorted the fonts into 'same' or 'similar' fonts so that one could remove the excess ones. Do you know of such a routine that works on Windows 10?


This Site

Got a version of Word that uses the ribbon interface (Word 2007 or later)? This site is for you! If you use an earlier version of Word, visit our WordTips site focusing on the menu interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.