Generating a List of Hyperlink Targets

Paul has a document that includes many hyperlinks. These are not only in the body of the document, but also in headers, footers, footnotes, and a few text boxes. He would like a way to copy the target addresses of all those hyperlinks to a new document. Paul imagines this must be done with a macro, but he doesn't know how to go about it.

There's actually a way to get hyperlinks into another document without using a macro—at least partially. You can follow these steps:

1. Open the document from which you want to cull the hyperlinks. (I'll call this the source document.)
2. Open a new, blank document. (I'll call this the target document.)
3. Switch back to the source document.
4. Press Alt+F9. Word displays the field codes instead of the results of field codes.
5. Press Ctrl+H. Word displays the Replace tab of the Find and Replace dialog box.
6. Switch to the Find tab.
7. In the Find What box, enter ^dHYPERLINK.
8. Select the Highlight All Items In check box.
9. Click Find All. Word selects all the hyperlinks in the document.
10. Press Esc to close the Find and Replace dialog box.
11. Press Ctrl+C. All the hyperlinks are copied to the Clipboard.
12. Switch to the target document.
13. Press Shift+Ctrl+V. The text of all of the hyperlinks is pasted into the document.

I say that this process copies hyperlinks "at least partially" because there are notable limitations to it. First, what you are copying is the hyperlink text displayed in the document, not the targets of the hyperlinks. As long as the actual URLs are displayed (when the field results are showing), then you are fine. Plus, the steps won't copy the hyperlinks targets that may be located in other areas, such as headers, footers, footnotes, etc.

Since Paul specifically said he wants the hyperlinks from wherever they may be in the document, then the best solution is to use a macro. This macro should do the job:

Sub ExtractHyperlinks()
    Dim dSource As Document
    Dim dTarget As Document
    Dim h As Hyperlink
    Dim sec As Section
    Dim hdrftr As HeaderFooter
    Dim shp As Shape
    Dim s As Range
    Dim iCount As Integer

    Set dSource = ActiveDocument
    Set dTarget = Documents.Add

    On Error Resume Next

    ' --- Body, footnotes, endnotes ---
    For Each s In dSource.StoryRanges
        Do
            For Each h In s.Hyperlinks
                dTarget.Content.InsertAfter h.Address & vbCr
                iCount = iCount + 1
            Next h
            Set s = s.NextStoryRange
        Loop Until s Is Nothing
    Next s

    ' --- Shapes / text boxes) ---
    For Each shp In dSource.Shapes
        If shp.TextFrame.HasText Then
            For Each h In shp.TextFrame.TextRange.Hyperlinks
                dTarget.Content.InsertAfter h.Address & vbCr
                iCount = iCount + 1
            Next h
        End If
    Next shp

    ' --- Headers/footers may contain shapes too ---
    For Each sec In dSource.Sections
        For Each hdrftr In sec.Headers
            For Each shp In hdrftr.Shapes
                If shp.TextFrame.HasText Then
                    For Each h In shp.TextFrame.TextRange.Hyperlinks
                        dTarget.Content.InsertAfter h.Address & vbCr
                        iCount = iCount + 1
                    Next h
                End If
            Next shp
        Next hdrftr
        For Each hdrftr In sec.Footers
            For Each shp In hdrftr.Shapes
                If shp.TextFrame.HasText Then
                    For Each h In shp.TextFrame.TextRange.Hyperlinks
                        dTarget.Content.InsertAfter h.Address & vbCr
                        iCount = iCount + 1
                    Next h
                End If
            Next shp
        Next hdrftr
    Next sec

    On Error GoTo 0
    MsgBox "Done! Found " & iCount & " hyperlinks."
End Sub

The macro checks everyplace that could contain hyperlinks, and then copies the target of those hyperlinks to a new document. The resulting document lists hyperlinks in no particular order, but they would be easy enough to sort, as desired.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13955) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.