Printing a List of Building Blocks

Karen would like to print out a list of all the Building Blocks available in Word, but can't seem to discover how to do it. You can print out a list of AutoText entries, but that is only a subset of the larger group of Building Blocks you could have on a system.

There is no built-in capability to print all the Building Blocks on a system, but you can create a macro to access the Building Block information. Building Blocks are stored in templates, with the Building Blocks.dotx template containing all the built-in Building Blocks. Therefore, you need to create a macro that steps through each template that you have open and grabs the building block information from each of them. Consider the following example:

Sub PrintBuildingBlocks()
    Dim oTemplate As Template
    Dim oBBT As BuildingBlockType
    Dim oCat As Category
    Dim oBB As BuildingBlock
    Dim J As Integer
    Dim K As Integer
    Dim L As Integer

    ' Loops through all of the open templates
    For Each oTemplate In Templates
        ' Prints the name of the template
        Selection.TypeText oTemplate.Name & vbCrLf
        For J = 1 To oTemplate.BuildingBlockTypes.Count
            Set oBBT = oTemplate.BuildingBlockTypes(J)
            ' Checks if the building block category has at least one entry
            If oBBT.Categories.Count > 0 Then
                ' Prints the name of the type of building block
                Selection.TypeText vbTab & oBBT.Name & vbCrLf
                For K = 1 To oBBT.Categories.Count
                    Set oCat = oBBT.Categories(K)
                    ' Prints the name of the category of the building block
                    Selection.TypeText vbTab & vbTab & oCat.Name & vbCrLf
                    For L = 1 To oCat.BuildingBlocks.Count
                        Set oBB = oCat.BuildingBlocks.Item(L)
                        ' Prints the name, description, and value
                        Selection.TypeText vbTab & vbTab & vbTab & _
                          "BB " & L & ": " & oBB.Name & vbCrLf
                        Selection.TypeText vbTab & vbTab & vbTab & _
                          "Description: " & oBB.Description & vbCrLf
                        Selection.TypeText vbTab & vbTab & vbTab & _
                          "Value: " & oBB.Value & vbCrLf & vbCrLf
                    Next L
                Next K
            Else
                ' Prints the name of the type of building block AND
                ' mentions that it does not contain any entries
                Selection.TypeText vbTab & oBBT.Name & _
                  " (no entries)" & vbCrLf
            End If
        Next J
    Next oTemplate
End Sub

For the best results, open a brand new document; it is this document into which the macro places the building block information. Before executing the macro, the Building Blocks.dotx should be opened by displaying the Insert tab of the ribbon, then clicking Quick Parts | Building Blocks Organizer. Displaying the Building Blocks Organizer in this manner ensures that Word opens the Building Blocks.dotx template.

When you execute the macro, it steps through each template, through each type of Building Block in the template, through each category in each type, and finally through each Building Block in each category. The name, description, and actual value for each Building Block is printed. This may not give as "pretty" of a result as you might hope because Building Blocks are much more than text—they can be full-fledged programs, as well. This may result in some funky characters in the document created by the macro.

There's also something else interesting to note about this macro. Note that the outside loop steps through each template using a For Each loop. This is rather normal and mundane for working through collections in the Word object model. However, the three nested loops within this outer loop uses a For Next loop because the collections involved (BuildingBlockTypes, Categories, and BuildingBlocks) don't support For Each loops.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (11096) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021.