Including a Printer's Name in a Footer

Abdul works in an office where he has access to five printers from his computer. When he prints a document, he wants the footer to contain the name of the printer on which the document was printed, as in "Printed on: HP LaserJet 1320."

Provided that the document is being sent to a specific printer and not to a printer pool to which all five printers belong, the necessary footer information can be added through the use of a macro. The reason that it cannot be done if the printers are in a pool is because divvying up the print jobs to individual printers in a print pool is done by Windows itself, not by Word.

For an example of a macro you could use, consider this one:

Sub AddPrinterName()
    Dim sPName As String

    ' Get the printer name
    sPName = Trim(Left(ActivePrinter, InStr(ActivePrinter, " on ")))

    ' Close any special pane
    If ActiveWindow.View.SplitSpecial <> wdPaneNone Then
        ActiveWindow.Panes(2).Close
    End If

    ' Activate print view
    If ActiveWindow.ActivePane.View.Type = wdNormalView _
      Or ActiveWindow.ActivePane.View.Type = wdOutlineView Then
        ActiveWindow.ActivePane.View.Type = wdPrintView
    End If

    ' Open header/footer
    ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader

    ' Switch to footer
    If Selection.HeaderFooter.IsHeader = True Then
        ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageFooter
    Else
        ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
    End If

    ' Insert text and printer
    Selection.TypeText Text:="Printed on: " & sPName

    ' Tidy up
    ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
End Sub

This macro will insert the active printer's name into the footer. You can, if desired, trigger this macro from the DocumentBeforePrint event and you'll be sure that the footer has the required information in it whenever you choose to print. If you do so, of course, you'll want to make sure that you modify the macro slightly so that it selects any previously placed footer information and deletes it before inserting the new footer information.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (9771) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, Word in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Word here: Including a Printer's Name in a Footer.