Sentences Containing a Search Term

Sara can use the search capabilities of Word to search for terms, such as "garrison." However, she would like to compile the search results, showing the entire sentence in which the found search term exists. Sara wonders if there is a method or tool to compose such a compilation.

Fortunately, Word provides a way that you can step through all the sentences in a document using VBA. This means that you can create a macro to find sentences containing your search term. Here's a simple example:

Sub CompileSentences()
    Dim docThis As Document
    Dim docThat As Document
    Dim sRaw As String
    Dim sWanted As String
    Dim J As Long

    sWanted = InputBox("Search Term")
    sWanted = Trim(LCase(sWanted))

    If sWanted > "" Then
        Set docThis = ActiveDocument
        Set docThat = Documents.Add

        For J = 1 To docThis.Sentences.Count
            sRaw = docThis.Sentences(J).Text
            sRaw = Trim(LCase(sRaw))
            If InStr(sRaw, sWanted) > 0 Then
                Selection.TypeText Text:=docThis.Sentences(J)
                Selection.TypeParagraph
            End If
        Next J
    End If
End Sub

The macro uses a For...Next loop to step through each of the sentences in the active document and checks whether those sentences contain the search term. If it does, then the sentence is added to a new document. You may wonder why a For...Next loop is used rather than a For...Each loop. The reason is easy—VBA allows you to access the Sentences collection, but there is no Sentence object in VBA; all access must be done by index number, as in this macro.

The macro also doesn't check to make sure that the search term is an entire word or not. Thus, if the sentence contained the word "garrisoned," and you were searching for "garrison," then the sentence would be considered a positive result. This approach was purposeful in case you wanted to search for multi-word phrases, such as "red cap" or "carrying case."

Note that the user is prompted to input what the search term should be. The search is case insensitive, and leading and trailing spaces are ignored. If the user doesn't enter anything when prompted, then the macro is exited.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (8564) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365.