Mass Search and Replace

Over time it is very possible to collect a huge number of documents. At some point you may want to make the same change to each of the documents in the collection. For instance, you may need to change the company name within each document. Obviously, you can open each document, make the change, and then save the document, but that process can quickly become tiring if you have hundreds or thousands of documents to process.

What to do? Consistent with the point that has been made in other issues of WordTips, anytime you have something that is mundane and tiresome to accomplish, you can often use a macro to handle the work for you. For instance, you could write a macro that would step through all the documents in a directory, load each in turn, search for and change the necessary text, and resave the document. This process is no different than the process you would follow manually, except that it is done under the control of the macro. This makes it much easier and faster.

The following is an example of a Word macro that could do the trick:

Public Sub MassReplace()
    Dim Directory As String
    Dim FType As String
    Dim FName As String

    Directory = "d:\temp"
    FType = "*.docx"

    ChDir Directory
    FName = Dir(FType)
    ' for each file you find, run this loop
    Do While FName <> ""
        ' open the file
        Documents.Open FileName:=FName

        ' search and replace the company name
        selection.Find.ClearFormatting
        selection.Find.Replacement.ClearFormatting
        With selection.Find
            .Text = "OldCompanyName"
            .MatchCase = True
            .Replacement.Text = "NewCompanyName"
        End With
        selection.Find.Execute Replace:=wdReplaceAll

        ' replace street address
        With selection.Find
            .Text = "OldStreetAddress"
            .Replacement.Text = "NewStreetAddress"
        End With
        selection.Find.Execute Replace:=wdReplaceAll

        ' replace the City, State, and Zip code
        With selection.Find
            .Text = "OldCityStateAndZip"
            .Replacement.Text = "NewCityStateAndZip"
        End With
        selection.Find.Execute Replace:=wdReplaceAll

        ' save and close the current document
        ActiveDocument.Close wdSaveChanges

        ' look for next matching file
        FName = Dir
    Loop
End Sub

This macro is quite powerful, and it allows you to not just change a company name, but also your company's address. All you need to do is make changes to specify which directory and drive to use in your search, as well as what the old and new company information is.

If dealing with macros is a little beyond what you want to tackle, there are also a number of different commercial products available that will work with Word documents. Various subscribers have suggested the following programs:

• Word Search and Replace (http://www.funduc.com/word_sr.htm)
• InfoRapid Search & Replace (http://www.inforapid.com/html/searchreplace.htm)
• MegaReplacer (http://www.editorium.com/14843.htm)

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (8477) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021. You can find a version of this tip for the older menu interface of Word here: Mass Search and Replace.