Generating a List of Unique Words

Hi, thanks for this useful maco, it works smoothly, with a snag: it doesn't list words with diacritcs (á, ï...). Is there any easy way to fix that?

How can this macro be modified to generate a list of all the unique words in MULTIPLE documents within a folder (output ONE word list for ALL the documents in that folder) with one word per line and the list in a separate document? (I don’t need the frequency of the words).

Also, is it possible to get the word list directly as a .txt file instead of a .docx file?

Thanks for this. Super helpful.

How do you make it so that the hyphenated term is considered one word (e.g. year-end)? As well, how do we include alphanumeric terms?

Ken as always you put the icing on the cake with your adaptations of the great macros created by Alan. Both of you are a great asset to the WORD and EXCEL community. Keep up the good work.

Hmm. It's saying my word count is like 26k words larger than what Word's automatic word count feature is saying. Which is accurate? (It's a scary thought, because that would make the word count of my novel horribly too high).

Another method I've used is to copy the text of the document (text only paste) into a scratch file, replace all the whitespace with paragraph marks, sort the file (case insensitive sort), and finally delete all duplicate lines using the method from Graham Mayor's page (http://www.gmayor.com/replace_using_wildcards.htm) by wildcard searching for
(*^13)@
and replacing with
\1
to remove the duplicate words.

Andy.

Excatly what I was looking for. Great solution! Thank you!

Depending on the vocabulary of the author, large documents can have over 5000 unique words. The above macro displays one word per line which means that the list will occupy around 100 pages. The macro below will write the list of words into a new document with five columns per page.

Sub UniqueWordList()
Dim wList As New Collection
Dim wrd
Dim chkwrd
Dim sTemp As String
Dim k As Long

For Each wrd In ActiveDocument.Range.words
sTemp = Trim(LCase(wrd))
If sTemp >= "a" And sTemp <= "z" Then
k = 0
For Each chkwrd In wList
k = k + 1
If chkwrd = sTemp Then GoTo nw
If chkwrd > sTemp Then
wList.Add Item:=sTemp, Before:=k
GoTo nw
End If
Next chkwrd
wList.Add Item:=sTemp
End If
nw:
Next wrd

sTemp = "There are " & ActiveDocument.Range.words.Count & " words " & _
"in " & ActiveDocument.Name & ", but there "
Documents.Add
With ActiveDocument.Styles("Normal")
With .ParagraphFormat
.SpaceBefore = 0
.SpaceAfter = 0
.LineSpacingRule = wdLineSpaceSingle
End With
.NextParagraphStyle = "Normal"
.NoSpaceBetweenParagraphsOfSameStyle = False
.Font.Name = "Times New Roman"
.Font.Size = 10
End With

sTemp = sTemp & "are only " & wList.Count & " unique words."
Selection.TypeText vbCrLf & sTemp & vbCrLf & vbCrLf

Selection.InsertBreak Type:=wdSectionBreakContinuous
With Selection.PageSetup.TextColumns
.SetCount NumColumns:=5
.EvenlySpaced = True
.LineBetween = True
.Width = CentimetersToPoints(2.8)
.Spacing = CentimetersToPoints(0.4)
End With

For Each chkwrd In wList
Selection.TypeText chkwrd & vbCrLf
Next chkwrd
End Sub

If you want to know how often a word appears then the macro UniqueWordCount will list unique words and give a count of how many times each word appears in the document.

Sub UniqueWordCount()
Dim wList As New Collection
Dim wCount As New Collection
Dim wrd
Dim chkwrd
Dim sTemp As String
Dim k As Long
Dim j As Long

For Each wrd In ActiveDocument.Range.words
sTemp = Trim(LCase(wrd))
If sTemp >= "a" And sTemp <= "z" Then
k = 0
For Each chkwrd In wList
k = k + 1
If chkwrd = sTemp Then
j = wCount(k) + 1
wCount.Remove (k)
If k > wCount.Count Or wCount.Count = 1 Then
wCount.Add Item:=j
Else
wCount.Add Item:=j, Before:=k
End If
GoTo nw
End If
If chkwrd > sTemp Then
wList.Add Item:=sTemp, Before:=k
wCount.Add Item:=1, Before:=k
GoTo nw
End If
Next chkwrd
wList.Add Item:=sTemp
wCount.Add Item:=1
End If
nw:
Next wrd

sTemp = "There are " & ActiveDocument.Range.words.Count & " words " & _
"in " & ActiveDocument.Name & ", but there "
Documents.Add
With ActiveDocument.Styles("Normal")
With .ParagraphFormat
.SpaceBefore = 0
.SpaceAfter = 0
.LineSpacingRule = wdLineSpaceSingle
End With
.NextParagraphStyle = "Normal"
.NoSpaceBetweenParagraphsOfSameStyle = False
.Font.Name = "Times New Roman"
.Font.Size = 10
End With

sTemp = sTemp & "are only " & wList.Count & " unique words."
Selection.TypeText vbCrLf & sTemp & vbCrLf & vbCrLf

Selection.InsertBreak Type:=wdSectionBreakContinuous
With Selection.PageSetup.TextColumns
.SetCount NumColumns:=5
.EvenlySpaced = True
.LineBetween = True
.Width = CentimetersToPoints(2.8)
.Spacing = CentimetersToPoints(0.4)
End With

For k = 1 To wList.Count
Selection.TypeText wList(k) & "(" & wCount(k) & ")" & vbCrLf
Next k
End Sub