Inserting Dashes between Letters in Words

Lorraine often works with transcripts of interviews. Interviewers will ask interviewees to spell out their names. When she types these up, she needs to insert dashes between letters to show they are being spelled, as in J-O-H-N D-O-E. Lorraine wonders if there is a way to select the name and then run a macro to capitalize the name and insert the requisite dashes between letters.

Macros are very well suited for doing this type of text processing. In fact, there are probably a dozen or so ways you could approach the problem in your macro. The following is a rather simple way to do it:

Sub CapDashNames()
    Dim sTemp As String
    Dim sName As String
    Dim J As Integer

    sTemp = UCase(Selection.Range.Text)   ' Make all uppercase
    If Len(sTemp) > 1 Then
        sName = ""
        For J = 1 To Len(sTemp) - 1
            ' Add new character to name
            sName = sName & Mid(sTemp, J, 1)
            If Mid(sTemp, J, 1) >= "A" And Mid(sTemp, J, 1) <= "Z" Then
                ' Add a dash if character was a letter
                sName = sName & "-"
            Else
                ' Character added was not a letter
                If Mid(sName, Len(sName) - 1, 1) = "-" Then
                    ' If there is a dash just before non-letter,
                    ' get rid of it
                    sName = Left(sName, Len(sName) - 2)
                    sName = sName & Mid(sTemp, J, 1)
                End If
            End If
        Next J
        ' Add final character
        sName = sName & Right(sTemp, 1)
        Selection = sName
    End If
End Sub

Basically, the macro steps through whatever you've selected and adds a dash after each alphabetic character. If that dash is then followed by a non-alphabetic character, then the dash is removed. (That way you don't, for example, end up with a dash before or after a space.)

In order to use the macro, simply select the name you want to modify, and then run the macro.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1354) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, Word in Microsoft 365, and 2021.