Getting Rid of Extra Spaces at the End of a Footnote

When Thomas is working with documents created by other people, one of the steps he goes through is to delete any spaces that occur just before a hard return. He can use Find and Replace to do this, and thereby get rid of any extra spaces at the end of a paragraph. However, if the extra spaces are at the end of a footnote, Word doesn't really get rid of the spaces. Instead, it replaces the hard return at the end of the footnote with an extra hard return, so Thomas ends up with hard return, space, hard return. He wonders how he can properly get rid of extra spaces at the end of footnotes.

This seems to be a relatively new quirk in Word, and it can be quite frustrating for those who deal with footnotes quite a bit. (It isn't clear which version of Word this behavior cropped up in, but it is definitely there in Microsoft 365.) One possibility is to convert your footnotes to endnotes, then do the deletion, then convert the endnotes back to footnotes. This approach works because Word doesn't exhibit the same quirk with endnotes as it does with footnotes. (Go figure!)

A better approach, however, may be to use a macro to do the space removal. This is an especially good way to go if you need to work with footnote-laden documents often. Here's a very simple macro that may work for you:

Sub RemoveFS()
    ' Removes spaces from the end of paragraphs within footnotes
    Dim f As Footnote

    For Each f In ActiveDocument.Footnotes
        If Right(f.Range.Text, 1) = " " Then
            f.Range.Text = Left(f.Range.Text, Len(f.Range.Text) - 1)
        End If
    Next f
End Sub

Note that the macro checks each footnote to see if it ends in a space. If it does, then it removes that space by simply setting the .Text property for the footnote to drop that last character.

There is a problem with this macro, however. If your footnotes contain formatted characters (bold, italic, etc.), then that formatting is removed. When it comes to footnotes, which are often used for citations to books and articles, this can be a deal breaker. In that case, a better approach is the one used in this macro:

Sub RemoveFS()
    ' Removes spaces from the end of paragraphs within footnotes
    Dim f As Footnote

    For Each f In ActiveDocument.Footnotes
        If Right(f.Range.Text, 1) = " " Then
            f.Range.Select
            Selection.Collapse Direction:=wdCollapseEnd
            Selection.TypeBackspace
        End If
    Next f
End Sub

This macro still checks to see if the footnote ends in a space, but if it does, it selects the footnote, collapses the insertion point to the end of the footnote, and then types a backspace character. Any character formatting within the footnote is left undisturbed.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (629) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, Word in Microsoft 365, and 2021.