Finding Tables that are Too Narrow or Too Wide

Orson has a document that is about 300 pages long and contains more than a hundred tables. The text area within the document is 6.5 inches. Orson needs a way to easily find any table that is less than 6.25 inches wide or more than 6.5 inches wide. This doesn't seem to be something he can do with Find and Replace, so he wonders if he will need a macro.

The short answer is yes, a macro is required to perform this type of analysis. Fortunately, the macro doesn't need to be very complex. It simply needs to step through each table, calculate the table width, and then make a determination of what to do if the width is outside of Orson's target width. The following macro performs exactly those steps:

Sub AnalyzeTableWidths()
    Dim tbl As Table
    Dim tblWidth As Double
    Dim tblCount As Long
    Dim sMsg As String
    Dim pg As Long
    Dim docReport As Document

    sMsg = ""
    tblCount = 0
    For Each tbl In ActiveDocument.Tables
        tblCount = tblCount + 1
        tblWidth = tbl.PreferredWidth / 72

        If tblWidth < 6.25 Or tblWidth > 6.5 Then
            pg = tbl.Range.Information(wdActiveEndPageNumber)
            If sMsg = "" Then
                sMsg = "Tables out of range (< 6.25"" or > 6.5""):"
                sMsg = sMsg & vbCrLf & vbCrLf
            End If
            sMsg = sMsg & "¥ Table #" & tblCount & " on page " & pg & _
            " (Width: " & Format(tblWidth, "0.00") & " in.)" & vbCrLf
        End If
    Next

    ' Show the results
    If sMsg = "" Then
        sMsg = "All tables are within the allowed width (6.25"" - 6.5"")."
    Else
        Set docReport = Documents.Add
        docReport.Content.Text = sMsg
        sMsg = "Scan complete! A summary report has been created "
        sMsg = sMsg & "in a new document."
    End If
    MsgBox sMsg, vbInformation, "Done"
End Sub

Note that the macro puts together a report in the sMsg string as it steps through each table. The report includes not only the width of the table, but also the page on which the table is located. When complete, if there is something in the report, then a new document is created and the report is placed there. If no tables were found outside the target width, then a message box to that effect is displayed.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13992) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.