Adjusting Column Width from the Keyboard

Many people who are familiar with WordPerfect later find the need to learn how to use Word. Sometimes the transition is not entirely smooth, in large part because tasks aren't accomplished the same way in Word as they are in WordPerfect.

A case in point is adjusting the width of table columns by using the keyboard. WordPerfect, which has always been a "keyboard oriented" program, makes the adjustments easy: just press > or < to widen or narrow the column. Word, on the other hand, has always been more mouse oriented and has no equivalent keyboard command for this task.

There are workarounds; for instance, you can use the keyboard to type Alt+A, R, U, and then press Tab a couple of times to get to the column width field. The problem with this, of course, is that it is not anywhere near easy (or intuitive).

If you don't mind using the mouse, you can hold down the Alt key as you drag a column border. The Ruler changes to show the precise width of your columns as you move the border. Very cool, but still a pain for those who would rather just use the keyboard. (It is also not terribly helpful for those who may not have very good mouse resolution or who cannot move the mouse very small distances.)

Perhaps the best solution is to make your own emulation of the WordPerfect capability. The following macro can do just that:

Sub StretchColumn()
    Dim iCol As Integer
    Dim sCurrent As Single

    If Selection.Information(wdWithInTable) Then
        If Selection.Columns.Count = 1 Then
            iCol = Selection.Cells(1).ColumnIndex
            sCurrent = Selection.Tables(1).Columns(iCol).Width
            Selection.Tables(1).Columns(iCol).SetWidth _
              ColumnWidth:=sCurrent + 1, RulerStyle:=wdAdjustNone
        Else
            MsgBox ("More than one column selected")
        End If
    Else
        MsgBox ("Insertion point not within a table")
    End If
End Sub

If you assign this macro to a shortcut key (as described in other issues of WordTips), then you can increase the width of the current table column by one point (1/72 of an inch) each time you press the shortcut key. You can make a simple change to the macro to create a version that decreases the column width, as well:

Sub ShrinkColumn()
    Dim iCol As Integer
    Dim sCurrent As Single
    Dim sNext As Single

    If Selection.Information(wdWithInTable) Then
        If Selection.Columns.Count = 1 Then
            iCol = Selection.Cells(1).ColumnIndex
            sCurrent = Selection.Tables(1).Columns(iCol).Width
            sNext = sCurrent - 1
            If sNext < 1 Then sNext = 1
            Selection.Tables(1).Columns(iCol).SetWidth _
              ColumnWidth:=sNext, RulerStyle:=wdAdjustNone
        Else
            MsgBox ("More than one column selected")
        End If
    Else
        MsgBox ("Insertion point not within a table")
    End If
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13369) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Office 365. You can find a version of this tip for the older menu interface of Word here: Adjusting Column Width from the Keyboard.