Leaving Even Pages Blank

@Tomek I appreciate all the thought you’ve given to this process. I had the same idea you did and rotated the pages in order to get the final printing for all of them. It worked perfectly, as did the right-hand leaf printing for new pages. Now, all new pages begin on the right (recto) side, as I wanted, without having the need for section breaks. Your final macro is the solution. I think Allen should put it in his rotation!

Thank you for all your help!

I succeeded getting the booklet printed correctly, ready to be folded with staples in the centre. It worked with even page section breaks as you suggested with blank pages on the right.

I had to try several times. Booklet setting in my printer driver, did not quite work. However, setting booklet in Word (Layout->margins-> Custom Margins->Multiple Pages-> Book fold) worked reasonably well, although I had to load paper for second side printing with different rotation than indicated in the pop-up message. My printer prints single-sided but supports double-sided printing stopping half way and asking to reload the partly printed sheets.

I had easier success saving the Word document as PDF and then printing from my PDF Reader (PDF-XChange Editor - highly recommended; has a free version too) as a double-sided booklet.

I hope this helps.
Please let me know if it worked for you, or if you have additional questions.

Hi @Linda:
First, I used odd-page breaks because that was what Allen used in his original tip. As you pointed out, this would leave even pages blank, and when you print the document (double sided and then bind it, the blank pages would be on the left, and your instructions on the right. To have a blank page also for the first page, you would have to add a blank sheet to the front. But that can be achieved by printing the whole thing single sided and adding an extra first sheet. If you want blank pages on the right and instructions on the left you can also achieve this by single-sided printing, but in **reverse** order, then binding the printed document on the right side of the pages with instructions with an extra sheet added at the end.
Many printers have the reverse-order print setting.

This would work for printed documents, including printing to the PDF format and saving to PDF format. However, if you wanted the Word document to be used on the computer, none of the solutions discussed so far would work, The skipped pages by using page breaks do not show on screen.

All what I said before got me feeling that none of this is what you really wanted. And then I noticed that you are creating a booklet, which for me means that you are printing two pages per sheet side, and then staple it in the centre and fold in half. I will test some things for this scenario and get back to you.

As for inserting even-page section breaks, it would require a slight modification of the macro to insert such section break also at the very beginning of the document. So the firs page would be blank, the second would have instructions, and then the remaining odd pages would be skipped. The final part of the macro wold be :

'------------------------------------------------
' Insert Even-Page Section Breaks:
    Selection.HomeKey Unit:=wdStory
    Selection.InsertBreak Type:=wdSectionBreakEvenPage
    Do
        Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, count:=1, Name:=""
        Selection.MoveLeft Unit:=wdCharacter, count:=1
        Selection.InsertBreak Type:=wdSectionBreakEvenPage
    Loop Until Selection.Information(wdActiveEndPageNumber) = Selection.Information(wdNumberOfPagesInDocument)
End Sub

@Tomek:
Thank you for the macro! I apologize for the late reply. I just now am about to use it (medical issues have prevented me), but don't I want to insert _Even_ Page breaks in order for each new page to begin on the right? The odd page would be on the left, correct?

@Linda:
Additional note: the comment in the section that inserts the section breaks suggests to remove a line there to process only from the cursor to the end of the document will not work, as the initial check for the manual page breaks already moves the cursor to the very start of the document.

Hi @Linda:
I have created a macro you asked for. The main part of the macro is quite simple, but it has a possibility to run in an endless loop, therefore I added some check before the actual insertion of breaks is done. Please read the comment lines inside the macro.
Let me know if it worked for you, and do not hesitate to contact me via e-mail (disclosed in this post) or post a comment here if you need any additional help or modification.
'===========================
Sub InsertMyBreaks()
'
' InsertMyBreaks Macro
' This will insert Odd-Page section breaks at the end of all pages, except the last one.
' The main par of the macro would run in an infinite loop, if you have any section breaks or any manual page breaks.
' Because of that the macro will first check for section breaks and for any manual page breaks and exit whent there are any.
' you can use find and replace to remove section breaks and or manual page breaks,
' or use associate macros: RemoveSectionBreaks RemoveManualPageBreaks.


'check for section breaks:
    If ActiveDocument.Sections.count > 1 Then
        MsgBox "Remove sections before running this macro"
        Exit Sub
    End If

' check for manual page breaks:
    Selection.HomeKey Unit:=wdStory
    
    ' Configure the Find operation
    With Selection.Find
        .ClearFormatting
        .Text = "^m" ' The special character code for a manual page break
        .Forward = True
        .Wrap = wdFindContinue ' Continue searching from the start/end of the document
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        
        ' Execute the Find operation and count occurrences
        If .Execute = True Then
            MsgBox "Remove manual page breaks before running the macro again"
            Exit Sub
        End If
        
    End With

' Insert Odd-Page Section Breaks:
    Selection.HomeKey Unit:=wdStory 'remove this line if you want to process
                                    'only lines after the current insertion point
    Do
        Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, count:=1, Name:=""
        Selection.MoveLeft Unit:=wdCharacter, count:=1
        Selection.InsertBreak Type:=wdSectionBreakOddPage
    Loop Until Selection.Information(wdActiveEndPageNumber) = Selection.Information(wdNumberOfPagesInDocument)
End Sub
'===============================================================================
Sub RemoveSectionBreaks()
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "^b"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub
'========================================================
Sub RemoveManualPageBrakes()
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "^m"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub

@Tony Nixon:
You are right for the printed document, but not if you want the training material to be used on the computer?

I am creating a booklet in which I want each new page to start on the right side. I know I can do this with Section breaks, but my "chapters" are only one page long each. It's a specialty booklet similar to a recipe book concept. Using Section breaks for 45 or 50 pages would "create a lot of complexity to the document" according to Microsoft MVP help. You mention there is a macro that might do something like this. I don't know how to write that, but I'm sure you or someone here does. :) I'd really appreciate it if someone has time! Thank you!

an obvious answer perhaps, but doesn't single sided printing provide a blank page for notes opposite every page of text?