Getting a Change and Comment Count by Author

Jackie uses Track Changes regularly in her department. She notes that it would be nice to be able to analyze a marked-up document to get a count of how many changes and how many comments were made by the various editors on the document.

Word does not provide that ability. You can, however, create a macro that may give you the information you desire. The following example steps through each revision in a document and accumulates the editor names and a count of each editor's changes.

Sub CountReviewers()
    Dim J As Integer
    Dim Cnt As Integer
    Dim sMsg As String
    Dim Authors(299) As String
    Dim aCount(299) As Long
    Dim aRev As Revision
    Dim bNew As Boolean

    Cnt = 0
    On Error GoTo RevNext

    For Each aRev In ActiveDocument.Revisions
        ' Check to see if this is a new author
        bNew = True
        For J = 1 To Cnt
            If aRev.Author = Authors(J) Then
                ' Already have author
                aCount(J) = aCount(J) + 1
                bNew = False
            End If
        Next J
        If bNew Then
            ' New author; add to list
            Cnt = Cnt + 1
            Authors(Cnt) = aRev.Author
            aCount(Cnt) = 1
        End If
RevNext:
    Next aRev

    ' Put together and display final report
    sMsg = ""
    For J = 1 To Cnt
        sMsg = sMsg & Authors(J) & " (" & Trim(Str(aCount(J))) & ")" & vbCrLf
    Next J
    sMsg = sMsg & "Total revisions:" & Str(ActiveDocument.Range.Revisions.Count)
    MsgBox sMsg
End Sub

There are a few things to remember when using a macro like this. First, it is hard-coded to handle up to 299 editors on the document. If you have more, just increase the number of elements by which the Authors() and aCount() arrays are dimensioned. Second, if your document is long and has a lot of edits, it can take a while for the macro to run. So, the longer and more heavily edited the document, the more patient you'll need to be.

Finally, it is possible that the macro may ingloriously crash with some documents. (Not all, but just some.) This seems to happen most often with documents that have a tracked change caused by an automatic field change. The error that is thrown by such a scenario cannot be trapped for some reason, as this problem seems to be rooted in either a VBA or Excel error.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13873) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021.