Automatic Blank Pages at the End of a Section

Word allows you to add several types of section breaks into your document. Two of the section break types result in the addition of blank pages to the document, if necessary. For instance, if you use an Odd Page section break, and the previous section ends on an odd page, then Word automatically inserts a blank even page so that the next section can start on the next odd page.

The problem with this is that Word inserts an absolutely blank page—it doesn't even print headers or footers on the page. If you prefer headers and footers or some other information on the page (such as "This page intentionally left blank"), then you cannot rely on Word's section breaks alone.

One approach is to manually look at a document and, if necessary, add your own invisible text that would "print" on the page that would otherwise be blank. You create invisible text by adding regular text and formatting it as white. White on white, when printed, is invisible. Word, however, doesn't realize this and provides headers and footers on the "blank" page.

An interesting approach is to create your own end-of-section standard text. Create a building block entry that contains your end-of-section text, including a page break at the beginning of the entry. Name the entry something like "BLANKPAGE." Then, at the end of each section, just before the section break, add the following compound field:

{ if { =int( {page} / 2 ) * 2 } = { page }  " " { autotext "BLANKPAGE" } }

Remember that the braces shown in this example are supposed to be field braces. You enter field braces by pressing Ctrl+F9 for each set. The field checks to see if the current page is, in this case, even. If it is, then the field automatically inserts your building block using the AUTOTEXT field.

If desired, you can also create a macro that will step through the document, look at each section, decide how many pages are in the section, and then add a page break at the end of the section, if necessary. The following macro does this very task:

Sub CheckSecLen()
    Dim iSec As Integer
    Dim oRng As Range
    Dim iValue As Integer

    With ActiveDocument
        ' go through each section (except for the last one)
        For iSec = 1 To .Sections.Count - 1
            ' create a range object at the start of the section
            Set oRng = .Sections(iSec).Range
            oRng.Collapse wdCollapseStart
            ' insert a sectionpages field
            .Fields.Add Range:=oRng, Type:=wdFieldSectionPages
            ' divide the sectionpages field by 2
            ' if it gives a zero as the remainder, then
            ' you have an even number of pages in the section,
            ' which is what you want with an odd section page break
            If (.Sections(iSec).Range.Fields(1).Result Mod 2) <> 0 Then
                ' if you have an odd number of pages, then insert
                ' a page break before the section's section break
                Set oRng = .Sections(iSec).Range
                With oRng
                    .Collapse Direction:=wdCollapseEnd
                    .MoveEnd unit:=wdCharacter, Count:=-1
                    .InsertBreak Type:=wdPageBreak
                End With
            End If
            ' remove the sectionpages field that was added
            .Sections(iSec).Range.Fields(1).Delete
        Next iSec
    End With
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (12565) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Automatic Blank Pages at the End of a Section.