Please Note: This article is written for users of the following Microsoft Word versions: 2007, 2010, 2013, and 2016. If you are using an earlier version (Word 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Word, click here: Changing What Is Pasted in a Dialog Box.

Changing What Is Pasted in a Dialog Box

by Allen Wyatt
(last updated July 14, 2018)

Ihor wants to automate the inserting of a URL hyperlink into a Word document. The URL will be associated with a phrase, such as "click here". He first copies the URL of a specific website to the Clipboard. He then records a macro that opens the Insert Hyperlink dialog box (Ctrl+K) and pastes into the appropriate field the URL from the Clipboard (Ctrl+V) and clicks OK. When he later runs the macro, it gives him the same URL every time he runs it. Ihor wants to paste a different URL into the dialog box every time he runs the macro, but seems to be missing how to do that.

When you record a macro, it is very literal about what it does—it records exactly the steps you take, including how dialog boxes are filled out. The solution isn't to look for ways to paste new information into a dialog box, but to look at how you are creating your hyperlink. Here's what would be recorded if you inserted a hyperlink with the macro recorder running:

Sub Macro1()
'
' Macro1 Macro
'
'
    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
        "http://www.tips.net/", SubAddress:="", ScreenTip:="", TextToDisplay:= _
        "click here"
End Sub

What Ihor wants to change is the target for the hyperlink, which is assigned to the Address property; this is what gets "pasted" into the Address field of the dialog box. In order to do this, you could change your macro in a simple manner, such as this:

Sub Macro2()
    Dim sTemp As String
    sTemp = "http://www.tips.net/"

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, _
      Address:= sTemp, SubAddress:="", ScreenTip:="", _
      TextToDisplay:= "click here"
End Sub

All that has been done in this example is delete some of the unnecessary comments at the beginning of the macro and create a string variable, sTemp, that now contains the target for the hyperlink. This variable is then assigned to the Address property. In order to change the target, then, one only needs to change the value of the sTemp variable—and there are a number of ways this can be done.

One way is to use an InputBox function to create your own dialog box, in this manner:

Sub Macro3()
    Dim sTemp As String
    Dim sPrompt As String
    Dim sTitle As String

    sPrompt = "Enter the target for the hyperlink"
    sTitle = "Hyperlink Destination"
    sTemp = "http://www.tips.net/"
    sTemp = InputBox(sPrompt, sTitle, sTemp)

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, _
      Address:= sTemp, SubAddress:="", ScreenTip:="", _
      TextToDisplay:= "click here"
End Sub

Of course, Ihor mentioned that in his process he actually copies the URL to the Clipboard. If that is the process that he wants to use, it is possible to assign the URL based on whatever is in the Clipboard when the macro is run. Here's how you would do that:

Sub Macro4()
    Dim sTemp As String
    Dim MyData As DataObject
    Set MyData = New DataObject

    MyData.GetFromClipboard
    sTemp = Trim(MyData.GetText(1))

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, _
      Address:= sTemp, SubAddress:="", ScreenTip:="", _
      TextToDisplay:= "click here"
End Sub

In order to utilize the Clipboard in this manner, you'll need to set up a reference for the Microsoft Forms in the VBA Editor. (Choose References from the Tools menu in the Editor.)

Note, as well, that all these examples modify what is assigned to the Address property of your new hyperlink. There is a good chance that you'll want to change the macro to modify what is assigned to the TextToDisplay property, as well.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the WordTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (11906) applies to Microsoft Word 2007, 2010, 2013, and 2016. You can find a version of this tip for the older menu interface of Word here: Changing What Is Pasted in a Dialog Box.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Rounding To the Nearest Even Integer

Do you need your numbers to be rounded to an even integer value? How you accomplish the task depends on the nature of the ...

Discover More

Forcing Printouts to Black and White

If you want to force Word to print some of its colors in black and white, you may be out of luck. One bright spot, as ...

Discover More

Controlling the Italic Text Attribute

If you are formatting your document by using a macro, you may need to make some of your text italics. You do that by ...

Discover More

Learning Made Easy! Quickly teach yourself how to format, publish, and share your content using Word 2013. With Step by Step, you set the pace, building and practicing the skills you need, just when you need them! Check out Microsoft Word 2013 Step by Step today!

More WordTips (ribbon)

Determining the Month of the Year

Your macro code may need to determine the month of the year represented by a particular date. You can find the desired ...

Discover More

Occurrences of a Text String within a Document

You may have a need to find out how many times a certain text string occurs within a document. You can find out manually ...

Discover More

Moving Through a Table in a Macro

Do you need to step through a table, cell by cell, in a macro? It's easy to do using the Move method, as described in ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 5 - 2?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Word that uses the ribbon interface (Word 2007 or later)? This site is for you! If you use an earlier version of Word, visit our WordTips site focusing on the menu interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.