Hidden Numbered Items Still Affect Numbering

Mabel uses numbering in her documents, both in regular numbered lists and in headings. When she applies the Hidden attribute to a portion of the document that happens to be numbered, the remaining numbered items do not get renumbered. Apparently, Word still takes the hidden numbered items into account even though they are hidden. Mabel needs Word to ignore the hidden items and skip their numbering, so that the visible lists and headings use properly sequential numbering when printed.

The short answer is no, Word cannot do this. The program takes hidden text into account in doing automatic numbering, and there is no way to change that. There are workarounds, however.

Perhaps the easiest workaround for the purpose Mabel describes is to simply delete the hidden items before printing. This may sound drastic, but is quite easy to do. You can use Find and Replace to delete the hidden text, then print the document, and finally close the document without saving. You can even use a macro to accomplish these three tasks:

Sub PrintWithoutHidden()
    Dim rng As Range

    ' Turn off screen updating
    Application.ScreenUpdating = False

    ' Save the document
    ActiveDocument.Save

    ' Remove hidden text
    Selection.HomeKey Unit:=wdStory
    Set rng = ActiveDocument.Content
    With rng.Find
        .ClearFormatting
        .Font.Hidden = True
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False

        Do While .Execute
            rng.Delete
        Loop
    End With

    ' Print the document
    ActiveDocument.PrintOut

    ' Close the document without saving changes
    ActiveDocument.Close SaveChanges:=wdDoNotSaveChanges

    ' Restore screen updating
    Application.ScreenUpdating = True
End Sub

Besides the three mentioned tasks, the macro saves the document before deleting the hidden text. It then deletes hidden text, prints the document to the current printer, and closes the document without saving.

The second workaround you could use depends on the use of styles. I'm going to assume that you are using a style called MyListItem for your numbered list paragraphs. All you need to do is to create a second style, which I'll call MyListItemHidden, and base it on the MyListItem style. Then, configure the MyListItemHidden style so that it has only two differences from the MyListItem style: (1) it is hidden, and (2) it uses a different numbering format or, alternatively, a bulleted format.

The benefit to this style-based approach is that you can easily switch the format of paragraphs between the MyListItem and MyListItemHidden formats and the numbering in the document is immediately updated.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10470) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.