Replacing an Image Filename with the Actual Image

Steve has a document with text that indicates where an image should be placed. This text consists of the image name (such as "image01.jpg") within parentheses. He is looking for a way to automatically replace each image name with the actual image.

This cannot be done with the regular Find and Replace capabilities of Word, but it can be done using a macro. The idea would be to search through the document for the marker text (the image names) and, if one is found, grab the image name and replace the marker text with the actual image. Here's a macro that implements these steps:

Sub ReplaceImages()
    Dim sMarkerText As String
    Dim sFigName As String
    Dim sFigPath As String

    ' Change to the path to the pictures, with a trailing slash.
    sFigPath = "C:\Users\Steve\Pictures\"

    ' Change to marker text. Can include wildcards.
    sMarkerText = "(image??.jpg)"

    ' Search through document for marker text
    Selection.Find.ClearFormatting
    With Selection.Find
        .Text = sMarkerText
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute
    While Selection.Find.Found
        ' Found a match, so grab name
        ' Need to adjust for parens in marker text
        sFigName = Mid(Selection, 2, Len(Selection) - 2)

        ' Delete the marker text
        Selection.Delete

        ' Insert the picture
        Selection.InlineShapes.AddPicture FileName:= _
          sFigPath & sFigName, LinkToFile:=False, _
          SaveWithDocument:=True
        Selection.Find.Execute
    Wend
End Sub

There are two things you need to modify in the macro code: the values stored in the sFigPath and sMarkerText variables. The sMarkerText contents, as shown, will match any parentheses in which the word "image" is followed by two characters (such as 01, 02, 97, or XY) and the ".jpg" extension.

The Find method of the Selection object implements an actual Find action for the very first occurrence of the marker text. If it is found, then the code in the While...Wend loop comes into play. This grabs the filename and assigns it to the sFigName variable. Then the found marker text is deleted and an inline image inserted in its place. Finally, the Selection.Find.Execute line finds the next occurrence of the marker text, if any.

The macro inserts images inline and does not do any additional processing on them.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10135) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021.