Highlight Words from a Word List

Paul has a document that he needs to check against a word list contained in another document. If the document being checked contains one of the words in the list, then the word in the document (not in the word list) needs to be highlighted. The word list is large, on the order of 20,000 words, and Paul is wondering what the best way to do this is.

The easiest way to do this is to write your own macro that will do the comparisons for you. Start by putting the words you want find in their own document. Put one word (or phrase) per paragraph (just press Enter after each word or phrase), and make sure the document is named "checklist.docx." With the document in the C: drive, the following macro can be used:

Sub CompareWordList()
    Dim sCheckDoc As String
    Dim docRef As Document
    Dim docCurrent As Document
    Dim p As Paragraph
    Dim sLookWord As String

    sCheckDoc = "c:\checklist.docx"

    If Dir(sCheckDoc) = "" Then
        MsgBox "Checklist file not found."
        Exit Sub
    End If

    Set docCurrent = ActiveDocument
    Set docRef = Documents.Open(sCheckDoc)
    Options.DefaultHighlightColorIndex = wdYellow

    With docCurrent.Content.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Format = True
        .MatchWholeWord = True
        .MatchCase = True
        .MatchWildcards = False
        .Wrap = wdFindContinue
        .Replacement.Highlight = True
        .Replacement.Text = "^&"

        For Each p In docRef.Paragraphs
            sLookWord = Trim(Replace(p.Range.Text, vbCr, ""))
            If Len(sLookWord) > 0 Then
                .Text = sLookWord
                .Execute Replace:=wdReplaceAll
            End If
        Next p
    End With

    docRef.Close False
End Sub

All you need to do is have the document open that you want checked, and then run the macro. If the document containing the words to check is named differently or in a different location, just change the line that sets sCheckDoc so that it has a different full path name for the document.

Basically, the macro grabs each word or phrase from checklist.docx and then does a Find and Replace operation using that word in the document. If the word is found, then it is highlighted in yellow. The macro also pays attention to case in what it finds. Thus, if your search word is "luckily," then it will only highlight the word if it is lowercase, meaning if a sentence begins with "Luckily," then it would not be highlighted.

You can put as many words in the checklist.docx document as you want, but understand that a Find and Replace is done for each of them. That means that if it contains a lot of words and the document you are searching is large, the macro can take quite a while to run. Paul said that he had 20,000 words that needed to be checked for, which means that the macro would do 20,000 Find and Replace operations. That may be enough time to take a lunch break while the macro is running.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (1173) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Highlight Words from a Word List.