Please Note: This article is written for users of the following Microsoft Word versions: 2007, 2010, 2013, and 2016. If you are using an earlier version (Word 2003 or earlier), this tip may not work for you. For a version of this tip written specifically for earlier versions of Word, click here: Character Frequency Count.

Character Frequency Count

by Allen Wyatt
(last updated June 24, 2017)

1

Scott is looking for a way to get a “frequency count” of all the characters in a document. He would like to know how many times each character, ASCII codes 9 through 255, occur. It is possible to use Find and Replace to determine the count of individual characters (simply search for a character in question and then replace it with itself), but such an approach would be tedious, at best, if you needed to do it for 247 different character codes to get the desired information.

Such a task must be done with a macro, but there are several ways to approach it. One way is to write a macro that will step through each member of the Characters collection, examining each, and assigning that character to one of a number of counters.

Sub CountChars1()
    Dim iCount(0 To 255) As Integer
    Dim i As Integer
    Dim vCharacter As Variant
    Dim sTemp As String

    ' Initialize the array
    For i = 0 To 255
        iCount(i) = 0
    Next i

    ' Fill the array
    For Each oCharacter In ActiveDocument.Characters
       i = Asc(oCharacter)
       iCount(i) = iCount(i) + 1
    Next

    ' Add document for results
    Documents.Add
    Selection.TypeText Text:="ASCII Character Count" & vbCrLf

    ' Only output codes 9 through 255
    For i = 9 To 255
        sTemp = Chr(i)
        If i < 32 Then sTemp = Trim(Str(i))
        sTemp = sTemp & Chr(9) & Trim(Str(iCount(i)))
        sTemp = sTemp & vbCrLf
        Selection.TypeText Text:=sTemp
    Next i
End Sub

The macro uses the iCount array to accumulate the counts of each character code, and then a new document is created to output the results. (The results document can be formatted in any way desired.)

This approach can work well for relatively short documents, up to a few pages. When the document gets longer, the macro gets slower. Why? Because it takes a great deal of time to use the Characters collection for some reason. If the macro runs too slow for your documents, then you will want to change it a bit so that it works solely with strings.

Sub CountChars2()
    Dim iCount(0 To 255) As Long
    Dim i As Long
    Dim j as integer
    Dim lCharCount As Long
    Dim sDoc As String
    Dim sTemp As String

    ' Initialize the array
    For i = 0 To 255
        iCount(i) = 0
    Next i

    ' Assign document to a huge string
    lCharCount = ActiveDocument.Characters.Count
    sDoc = ActiveDocument.Range(0, lCharCount)

    ' Fill the array
    For i = 1 to Len(sDoc)
       j = Asc(Mid(sDoc, i, 1))
       iCount(j) = iCount(j) + 1
    Next

    ' Add document for results
    Documents.Add
    Selection.TypeText Text:="ASCII Character Count" & vbCrLf

    ' Only output codes 9 through 255
    For i = 9 To 255
        sTemp = Chr(i)
        If i < 32 Then sTemp = Trim(Str(i))
        sTemp = sTemp & Chr(9) & Trim(Str(iCount(i)))
        sTemp = sTemp & vbCrLf
        Selection.TypeText Text:=sTemp
    Next i
End Sub

Notice that this version of the macro stuffs the entire document into a single string, sDoc. This string can then be processed very quickly by the macro. (A 635-page document only took about 30 seconds to process on my system.) Because this version is made to work with longer documents, note as well that some of the variable types have been changed to reflect the likelihood of larger counts.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (112) applies to Microsoft Word 2007, 2010, 2013, and 2016. You can find a version of this tip for the older menu interface of Word here: Character Frequency Count.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Grabbing a User's Name from Excel

One of the settings you can make in Excel is to specify a user's name. This name is accessible through macros, and can ...

Discover More

Deleting Old Data from a Worksheet

If you keep on-going data in a worksheet, some of your data—over time—may need to be deleted. If you have an ...

Discover More

Disabling Dragging and Dropping

Excel allows you to easily paste information into a worksheet, including through simply dragging and dropping the ...

Discover More

Learning Made Easy! Quickly teach yourself how to format, publish, and share your content using Word 2013. With Step by Step, you set the pace, building and practicing the skills you need, just when you need them! Check out Microsoft Word 2013 Step by Step today!

More WordTips (ribbon)

Selecting to the Next Punctuation Mark

Writing macros often involves selecting different parts of your document so that some sort of processing can be performed. If ...

Discover More

Determining the Size of a File

When processing a document using a macro, you may need to know the precise size of a particular file. The way you figure this ...

Discover More

Jumping to the Top of a Page

Do you want to easily jump to the top of a page in your document? You can use the Go To command to make the shift, or you can ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 8Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 5 + 0?

2017-06-26 11:40:25

Al Wilson

I get different results when I run the macros on the same document.


This Site

Got a version of Word that uses the ribbon interface (Word 2007 or later)? This site is for you! If you use an earlier version of Word, visit our WordTips site focusing on the menu interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in WordTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.