Copying Custom Properties

Custom document properties are a great way to store unique information that is associated with a document. For instance, you may have a company-assigned document number that needs to be stored with a document. A custom property fits the bill quite nicely for this purpose.

As you add custom properties to a document, you may start wondering if there is an easy way to copy them from one document to another. Unfortunately, there is no way to do this. (In my estimation, this capability would make a fine addition to the Organizer.) You can, however, create a macro that will do the copying for you. The following macro will do just that:

Sub CopyDocProps()
    Dim dp() As DocumentProperty
    Dim CustomPropCount As Integer
    Dim i As Integer
    Dim iResponse As Integer

    If Windows.Count > 2 Then
        MsgBox "There are more than two windows. Please " & _
          "close the others and re-run the macro.", , _
          "Too many windows"
        Exit Sub
    End If

    On Error GoTo Err_Handler

    iResponse = MsgBox("Are you currently in the source document?", _
      vbYesNoCancel, "Copy Custom Properties")

    If iResponse = vbNo Then Application.Run MacroName:="NextWindow"

    CustomPropCount = ActiveDocument.CustomDocumentProperties.Count
    ReDim dp(1 To CustomPropCount)

    For i = 1 To CustomPropCount
        Set dp(i) = ActiveDocument.CustomDocumentProperties(i)
    Next i

    Application.Run MacroName:="NextWindow"

    For i = 1 To CustomPropCount
        If dp(i).LinkToContent = True Then
            ActiveDocument.CustomDocumentProperties.Add _
              Name:=dp(i).Name, _
              LinkToContent:=True, _
              Value:=dp(i).Value, _
              Type:=dp(i).Type, _
              LinkSource:=dp(i).LinkSource
        Else
            ActiveDocument.CustomDocumentProperties.Add _
              Name:=dp(i).Name, _
              LinkToContent:=False, _
              Value:=dp(i).Value, _
              Type:=dp(i).Type
        End If
    Next i

    MsgBox "The properties have been copied."
    Exit Sub

Err_Handler:
    ' if Word raises an error, then allow the user
    ' to update the custom document property
    
    iResponse = MsgBox("The custom document property (" & _
      dp(i).Name & ") already exists." & vbCrLf & vbCrLf & _
      "Do you want to update the value?", vbYesNoCancel, _
      "Copy Custom Properties")

    Select Case iResponse
        Case vbCancel
            End
        Case vbYes
            ActiveDocument.CustomDocumentProperties(dp(i).Name).Value _
              = dp(i).Value
            Resume Next
        Case vbNo
            Resume Next
    End Select
End Sub

This code is an example of how to copy custom properties, but it is not bulletproof. For instance, it does not check to see if there are actually any custom properties in the source document; it just assumes that there are. Such coding could be easily added, however.

In order to use the macro, make sure that you have only the source and target documents open, and you should only have one window open per document. When the macro is finished, you will need to save the target document.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (11671) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Copying Custom Properties.