Printing Color Separations with VBA

Word does not have the inherent capability to print color separations. Instead, you typically must use a full-featured desktop publishing program such as InDesign to accomplish this task. That being said, you can perform a rudimentary form of color separation by simply changing the text color you don't want to print to white, and then printing the document. Reversing the process will then print the other color.

For instance, the following VBA macro will allow you to print color-separated text for a document that contains both red and black text:

Sub PrintSeps()
    ActiveDocument.Save
    Selection.HomeKey Unit:=wdStory

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting

    'Change Red to White
    Selection.Find.Font.ColorIndex = wdRed
    Selection.Find.Replacement.Font.ColorIndex = wdWhite
    With Selection.Find
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    ActiveDocument.PrintOut

    'Change White back to Red
    Selection.Find.Font.ColorIndex = wdWhite
    Selection.Find.Replacement.Font.ColorIndex = wdRed
    Selection.Find.Execute Replace:=wdReplaceAll

    'Change Auto to White
    Selection.Find.Font.ColorIndex = wdAuto
    Selection.Find.Replacement.Font.ColorIndex = wdWhite
    Selection.Find.Execute Replace:=wdReplaceAll

    'Change Black to White
    Selection.Find.Font.ColorIndex = wdBlack
    Selection.Find.Replacement.Font.ColorIndex = wdWhite
    Selection.Find.Execute Replace:=wdReplaceAll

    'Change Red to Black
    'This is done so that Red will print as Black
    'On some printers, non-black colors always
    'print as a shade of gray. You want them only
    'as black
    Selection.Find.Font.ColorIndex = wdRed
    Selection.Find.Replacement.Font.ColorIndex = wdBlack
    Selection.Find.Execute Replace:=wdReplaceAll

    ActiveDocument.PrintOut

    ActiveWindow.Close SaveChanges:=wdDoNotSaveChanges
End Sub

Note a couple of things about the PrintSeps macro. First, it saves your document. This is done because when the macro is done running, it throws out the document. Saving allows you to load the document from disk at a later time. The other thing to note is that this works only for documents that contain only red and black text. If you have other colors, those colors will print on both passes. If you have white text, it will print with the red pass. If you have graphics, no separation is done on them. (If you have graphics and want them separated, you definitely should be using a desktop publishing program.)

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (11243) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Printing Color Separations with VBA.