Turning Track Changes Off for Selected Areas

Carl's office makes extensive use of the Track Changes feature in Word, with the documents going through multiple individuals and multiple revisions prior to finalization. The Track Changes feature works very well for this purpose, with one exception: the document includes, in the footer, a date field (saved date), and each time the document is saved, Track Changes automatically strikes out the existing date and inserts a new last-saved date. This quickly results in a multi-line footer of revised last-saved date fields. Carl wondered if there is a way to tell Word to "ignore" the footer (or a specified field, block of text, section, etc.) when using Track Changes.

The short answer is that no, there isn't any way to do this. The Track Changes feature is either on or off for the entire document. This means that you have only a couple of options. The first option is to make the date in the footer static, so that it doesn't change. You could replace it with text (instead of using a field) and then simply remember to update the date as one of the last steps before finishing or printing the document.

Another option is to always accept the change to the footer whenever you open the file in Word. Simply right-click the date in the footer and then choose to Accept Change.

You can also "lock" the date in the footer. Just select the date field and press Ctrl+F11. This means that the field won't be updated and, therefore, won't show as changed when working in the document. When you are done developing the document, you can always unlock the field by again selecting it and pressing Ctrl+Shift+F11.

Still another option is to use a macro to save your document (if this is the point where the footer is being updated). The following macro accomplishes several things, and can be assigned to a toolbar button for ease of use. First, it steps through all the footers in the document and updates all the fields in the footers. It then accepts any revisions in those footers. Finally, it saves the document.

Sub Save_NoFooterRevisions()
    Dim rFooter As Range
    Dim iSectCount As Integer
    Dim j As Integer

    iSectCount = ActiveDocument.Sections.Count

    For j = 1 To iSectCount
        Set rFooter = ActiveDocument.Sections(j) _
          .Footers(wdHeaderFooterPrimary).Range
        With rFooter
            .Fields.Update
            .Revisions.AcceptAll
        End With
        Set rFooter = ActiveDocument.Sections(j) _
          .Footers(wdHeaderFooterEvenPages).Range
        With rFooter
            .Fields.Update
            .Revisions.AcceptAll
        End With
        Set rFooter = ActiveDocument.Sections(j) _
          .Footers(wdHeaderFooterFirstPage).Range
        With rFooter
            .Fields.Update
            .Revisions.AcceptAll
        End With
    Next j
    ActiveDocument.Save
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10807) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Turning Track Changes Off for Selected Areas.