Using Sequential Document Serial Numbers

If you have a need to create serial numbers in your documents and they are very simple in nature, you can do so using a macro. This approach to serial numbers is great if your serial numbers are sequential (1, 2, 3, etc.) or regular in their incidence (3, 5, 7, etc.).

To begin, you should create the macro that will control the changing of the serial number and the printing of your document. You can use the following macro:

Sub MySerial()
    Dim docCurrent As Document
    Dim rSerial As Range
    Dim iSerialNum As Integer
    Dim sTemp As String
    Dim iCopies As Integer
    Dim iCount As Integer

    Set docCurrent = Application.ActiveDocument
    Set rSerial = docCurrent.Bookmarks("Serial").Range

    ' Get the starting number. Note that the serial number
    ' needs to consist only of digits (no leading letters or
    ' symbols) in order for the Val function to work properly.
    iSerialNum = Val(rSerial.Text)

    ' Get the number of copies required
    sTemp = InputBox("How many copies?", "Print Serialized", "1")
    iCopies = Val(sTemp)

    For iCount = 1 To iCopies
        ' Print the document
        docCurrent.PrintOut Range:=wdPrintAllDocument
        ' Increment the serial number
        iSerialNum = iSerialNum + 1
        ' Convert to formatted number (with leading zeroes)
        ' and put back into the document.
        sTemp = Format(iSerialNum, "00000")
        rSerial.Text = sTemp
    Next iCount

    ' Reset the bookmark, since the updating procedure
    ' wipes out the old one.
    docCurrent.Bookmarks.Add Name:="Serial", Range:=rSerial
End Sub

There is only one prerequisite to using the macro: you need to make sure that your document contains a bookmark named Serial. This bookmark should reference the serial number in your document, as you want it to appear in the first printed document. The macro assumes that the serial number will be something like "00010" or "00123", with the leading zeroes. Thus, your bookmark (Serial) should reference the five digits that constitute your serial number.

If you want your serial number to be formatted differently, then you'll need to change the macro. Don't forget that the macro assumes the serial number can be converted directly to a value that can be incremented. So, if your bookmarked serial number starts with a letter (such as "Copy 001"), that will never increment properly. Instead, bookmark only the numeric portion.

When you are through running the macro, you can save the document and the serial number will be ready for the next time you want to use it.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (9540) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021. You can find a version of this tip for the older menu interface of Word here: Using Sequential Document Serial Numbers.