Detecting if the Insertion Point is Inside a Bookmark

Denise is developing a macro, and she needs to test to see if the insertion point is located within a bookmark. She needs to know this because if the insertion point is in a bookmark, she needs to have the code modify the bookmark; if it isn't in a bookmark, then her code needs to create one.

In theory the process is quite simple. All you need to do is check to see how many bookmarks there are in the selection, in this manner:

If Selection.Bookmarks.Count > 0 Then
    ' Inside a bookmark
End If

This works whether the selection is a range of text or the selection is collapsed to just the insertion point. There are a couple of potential "gotchas" to be aware of, however. The first is that if the insertion point is immediately to the left of a bookmark (just touching the start of the bookmark), the Count property will still be greater than 0. This is because the Selection that is defined by the collapsed insertion point is considered to include the character just to the right of the insertion point.

The second thing to be aware of is that if your selection is collapsed, you can't rely on the Count property being either 0 or 1. Indeed, it could be more than 1 because it is possible for bookmarks to "overlap" and, therefore, for the insertion point to be within more than one bookmark simultaneously. You may, therefore, need your code to test which bookmarks the insertion point is within. The easiest way to do this is to examine the Name property of the bookmarks, in this manner:

Dim bFoundIt As Boolean
Dim J As Integer

bFoundIt = False
Selection.Collapse
If Selection.Bookmarks.Count > 0 Then
    ' Inside a bookmark
    For J = 1 To Selection.Bookmarks.Count
        If Selection.Bookmarks(J).Name = "DesiredName" Then
            bFoundIt = True
        End If
    Next J
End If

When this code is executed, bFoundIt will be True only if the insertion point is within the desired bookmark. Note, as well, the inclusion of a command to collapse the selection to ensure it really in an insertion point and not a range of selected text.

A third potential "gotcha" is that Word actually uses bookmarks internally for many purposes. For instance, it uses them to define print ranges, but that isn't the only place. System-defined bookmarks can be detected, however, because they always begin with an underscore. While this wouldn't be a problem in the foregoing code (since you specifically are looking for a bookmark with a particular name), it would be a potential problem if your code is looking for any bookmark. The following code, written as a callable function, may be helpful in such a situation.

Function InBookmark() As Boolean
    ' Returns True if the insertion point is inside
    ' any non-system bookmark. Also collapses the
    ' selection to an insertion point

    Dim bFoundIt As Boolean
    Dim J As Integer

    bFoundIt = False
    Selection.Collapse

    For J = 1 To Selection.Bookmarks.Count
        If Left(Selection.Bookmarks(J).Name,1) <> "_" Then
            bFoundIt = True
        End If
    Next J

    InBookmark = bFoundIt
End Function

To use this function from within your macro, you could use something as simple as this:

If Not InBookmark Then
    ' create new bookmark
End If

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (6905) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365.