Converting Paragraphs to Comments

When developing a document, it is not unusual to use a particular paragraph style for editorial notes. For instance, the notes may be stored in paragraphs using a style called "Notes". At some point, you may want to take all the paragraphs that use the Notes style and convert them to actual comments in the document. You can go through the document and make the conversion manually, but this can quickly get tedious. Instead, use a macro that does the conversion for you:

Sub ConvertNotesToComments()
    Dim CommentText As String
    Dim MyRange As Range
    Dim iPCount As Integer
    Dim J As Integer

    Application.ScreenUpdating = False
    iPCount = ActiveDocument.Paragraphs.Count

    For J = iPCount To 1 Step -1
        If ActiveDocument.Paragraphs(J).Style = _
          ActiveDocument.Styles("Notes") Then
            Set MyRange = ActiveDocument.Paragraphs(J).Range
            CommentText = MyRange.Text

            'Get rid of trailing end-of-paragraph mark
            CommentText = Left(CommentText, Len(CommentText) - 1)

            'Move selection to end of previous paragraph
            MyRange.Collapse (wdCollapseStart)
            MyRange.Move Unit:=wdCharacter, Count:=-1

            'The original paragraph is no longer necessary
            ActiveDocument.Paragraphs(J).Range.Delete

            'Create the comment at the range location
            ActiveDocument.Comments.Add Range:=MyRange, _
              Text:=CommentText
        End If
    Next J
    Application.ScreenUpdating = True
End Sub

The macro steps backwards through the document, looking at the style of each paragraph. If it finds one that uses the Notes style, then it moves the text of the paragraph into the CommentText variable, and then gets rid of the paragraph. The comment is then added to the end of the paragraph prior to where the deletion was made.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13382) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Office 365. You can find a version of this tip for the older menu interface of Word here: Converting Paragraphs to Comments.