Finding a Cell Reference

When you are working with tables, you often need to know the reference of a particular cell. For certain functions or fields, Word expects the cell reference to be specified using the Column/Row format that many readers are familiar with in Excel. For instance, A1 is the top-left cell, B1 is one cell to the right, and A2 is one cell below the first cell.

Unfortunately, there is no inherent capability of Word to inform you of the reference of a cell you have selected. You can get around this problem by using a macro. The following example macro will return, in the status bar, the current column and row in which the insertion point is located.

Sub CellRef()
    Const clngAOffset As Long = 64
    ' Word's maximum columns is 64, but this procedure
    ' can cope up to clngMaxCols columns
    Const clngMaxCols As Long = 702
    Dim lngRow As Long, lngCol As Long
    Dim strCol As String

    ' See if in table
    If Selection.Information(wdWithInTable) Then
        ' Get column and row numbers
        lngCol = Selection.Information(wdStartOfRangeColumnNumber)
        lngRow = Selection.Information(wdStartOfRangeRowNumber)
        ' Convert column number to letter
        Select Case lngCol
        Case Is < 27
            ' Single character column reference
            strCol = Chr(clngAOffset + lngCol)
        Case Is > clngMaxCols
            MsgBox "Table is too big"
            Exit Sub
        Case Else
            ' Two-character column reference
            strCol = Chr(clngAOffset + Fix((lngCol - 1) / 26))
            strCol = strCol & Chr(CLng(clngAOffset + 1 _
              + ((lngCol - 1) Mod 26)))
        End Select
        ' Show column, row, and cell reference in status bar
        StatusBar = "Col:" & lngCol & "/Row:" & lngRow _
          & " = Cellref: " & strCol & CStr(lngRow)
    End If
End Sub

When you run the macro, it displays the requested information on the status bar in the following format:

Col:2/Row:1 = B1

You should note that the macro will handle tables that have more dimensions that Word will natively handle. This was not arbitrarily done; programmatically it is just as easy to return the 702nd column of a table (column ZZ) as it is to return the 64th column (column BL).

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13093) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Finding a Cell Reference.