Inserting the Time Remaining Until a Target Date and Time

Michael can use a field to insert a date and time into a document. He would like, however, to insert the "time remaining" until some date and time in the future. For instance, if the future date and time is 6:00 am on December 1, the "time remaining" would show as "DDD:HH:MM (Dec. 1, 2022 6:00 am)," with DDD being days, HH being hours, and MM being minutes.

This cannot be done using fields, but it can be done using a macro. And, you can make it at least semi-automatic if your macro relies upon the use of document variables. Consider the following rather short macro:

Sub CalcDateInterval()
    Dim dTargetDate As Date
    Dim dFromNow As Date
    Dim sTemp As String
    Dim v As Variable

    dTargetDate = DateValue("1 December 2022") + TimeValue("6:00:00 AM")
    dFromNow = dTargetDate - Now()

    sTemp = Format(Int(dFromNow), "#,##0") _
      & Format(dFromNow, ":hh:mm") & " " _
      & Format(dTargetDate, "(mmm. d, yyyy h:mm am/pm)")

    For Each v In ActiveDocument.Variables
        If v.Name = "CountDown" Then v.Delete
    Next v
    ActiveDocument.Variables.Add Name:="CountDown", Value:=sTemp
End Sub

The macro uses the future date and time (set in the dTargetDate variable) to calculate the number of days, hours, and minutes between now and then. This information is then formatted into the desired text string and placed into a document variable named CountDown.

Since the desired information is in a document variable, you can now use a field to reference the value of that variable. Here is the format of the field you would use:

{ DOCVARIABLE "CountDown" }

Every time you want to recalculate the countdown value, just re-run CalcDateInterval and update your fields. You could, if desired, set up CalcDateInterval as part of an event handler (so it is run automatically based on whatever event is being handled), but you will still need to update the fields to see the result in your document.

Remember, as well, that the countdown value (the string put together according to your desires) will not be "live"; it won't show an actual countdown that updates every minute. The value returned by the DOCVARIABLE field will only update when you update fields, and that is predicated on the updating of the actual document variable by using the CalcDateInterval macro.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (12822) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, Word in Microsoft 365, and 2021.