Generating a Markup Report

Hillary's team uses Track Changes and comments while developing documents. She notes that it would be handy to generate a report that indicates information about the changes, such as how many changes and comments there are, when the first change was made, when the last change was made, etc. Hillary wonders if there is a tool that will provide this sort of analysis.

The traditional way to get this sort of information is to print a list of markup by using these steps:

1. Press Ctrl+P. Word displays your printing settings.
2. Under the Settings heading is a drop-down list that is set, by default, to Print All Pages. (This is the very first drop-down list under the Settings heading.)
3. Using this drop-down list, choose List of Markup.
4. Click the Print button.

If you study what is produced in the printed list, you may find it provides just what you need. If not, then you'll want to try using a macro to analyze the changes in the document to pull out the desired information. The following will provide the simple information that Hillary requested:

Sub SummarizeMarkup()
    Dim rev As Revision
    Dim cmt As Comment
    Dim firstRevDate As Date
    Dim lastRevDate As Date
    Dim firstCmtDate As Date
    Dim lastCmtDate As Date
    Dim revDate As Date
    Dim cmtDate As Date
    Dim revInitialized As Boolean
    Dim cmtInitialized As Boolean
    Dim msg As String

    ' Get earliest/last change dates
    revInitialized = False
    For Each rev In ActiveDocument.Revisions
        revDate = 0
        On Error Resume Next
        revDate = CDate(rev.Date)
        On Error GoTo 0

        If revDate > 0 Then
            If Not revInitialized Then
                firstRevDate = revDate
                lastRevDate = revDate
                revInitialized = True
            Else
                If revDate < firstRevDate Then firstRevDate = revDate
                If revDate > lastRevDate Then lastRevDate = revDate
            End If
        End If
    Next rev

    ' Get earliest/last comment dates
    cmtInitialized = False
    For Each cmt In ActiveDocument.Comments
        cmtDate = 0
        On Error Resume Next
        cmtDate = CDate(cmt.Date)
        On Error GoTo 0

        If cmtDate > 0 Then
            If Not cmtInitialized Then
                firstCmtDate = cmtDate
                lastCmtDate = cmtDate
                cmtInitialized = True
            Else
                If cmtDate < firstCmtDate Then firstCmtDate = cmtDate
                If cmtDate > lastCmtDate Then lastCmtDate = cmtDate
            End If
        End If
    Next cmt

    ' Output summary
    msg = "Document Review Summary:" & vbCrLf & vbCrLf & _
      "Tracked Changes" & vbCrLf & _
      "   Total: " & ActiveDocument.Revisions.Count & vbCrLf

    If revInitialized Then
        msg = msg & _
          "   First: " & Format(firstRevDate, "m/d/yyyy h:mm AM/PM") & vbCrLf & _
          "   Last: " & Format(lastRevDate, "m/d/yyyy h:mm AM/PM") & vbCrLf
    Else
        msg = msg & _
          "   No date information available for changes" & vbCrLf
    End If

    msg = msg & vbCrLf & _
      "Comments" & vbCrLf & _
      "   Total: " & ActiveDocument.Comments.Count & vbCrLf

    If cmtInitialized Then
        msg = msg & _
          "   First: " & Format(firstCmtDate, "m/d/yyyy h:mm AM/PM") & vbCrLf & _
          "   Last: " & Format(lastCmtDate, "m/d/yyyy h:mm AM/PM")
    Else
        msg = msg & _
          "   No date information available for comments"
    End If

    MsgBox msg, vbInformation, "Document Markup Summary"
End Sub

The macro steps through the tracked changes and determines the earliest and latest dates, then does the same for the comments. The summary information displayed indicates the numbers and dates for both changes and comments. The macro could be expanded, as desired, based on analyzing the other properties stored by Word for each change or comment.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (9443) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.