Finding and Replacing in Headers and Footers

Eppa needs to replace a company name in a document. The name appears throughout the document, and also in the header and footer. The document has multiple sections. Eppa can use Find and Replace to replace within the document itself, but it won't make replacements in the headers and footers for some reason. So, Eppa wonders if there is some setting that will cause Find and Replace to make the necessary replacements in the header and footer at the same time it does so in the document.

This is a more involved question that it may, at first, appear. Using Word on a Microsoft 365 installation, doing a simple text replacement using Find and Replace did exactly what Eppa wanted—it replaced the text in the main document and in the headers and footers.

If Word does not replace in the headers and footers for some reason, then there is a two-pass approach you can try out. Let's say that your document has an old company name ("Harris Electric") and that you want to replace that with a new company name ("Davis Services"). Follow these steps:

1. Press Ctrl+H. Word displays the Replace tab of the Find and Replace dialog box.
2. In the Find What box, enter the old company name ("Harris Electric").
3. In the Replace With box, enter the new company name ("Davis Services").
4. Click Replace All. This replaces all the instances of the name in the main document, and Word displays a dialog box indicating how many replacements it made.
5. Click OK to dismiss the information dialog box. (The Find and Replace dialog box should still be visible.)
6. Display the Find tab.
7. Click the Find In drop-down list. Word displays some options.
8. Choose the Header and Footer option.
9. Display the Replace tab.
10. Click, again, on Replace All. This replaces all the instances of the name in the headers and footers. Word, again, displays a dialog box indicating how many changes were made.
11. Click OK to dismiss the information dialog box.
12. Click Close to dismiss the Find and Replace dialog box.

If you need to replace the company name in a lot of documents, then it may be better to use a macro. Here's an example of a macro that will make replacements in the main document and then in each header and footer in all the sections of the document:

Sub ReplaceInHeadersFooters()
    Dim sec As Section
    Dim hdr As HeaderFooter
    Dim ftr As HeaderFooter
    Dim rng As Range
    Dim findText As String
    Dim replaceText As String
    Dim StartMsg1 As String
    Dim StartMsg2 As String
    Dim EndMsg As String

    ' Set initial information
    StartMsg1 = "Enter the text to find:"
    StartMsg2 = "Enter the replacement text:"
    EndMsg = "Replacement completed in document, headers, and footers!"

    ' Set the text to find and replace
    findText = InputBox(StartMsg1, "Find Text")
    replaceText = InputBox(StartMsg2, "Replace Text")

    ' Replace in main document body
    Selection.HomeKey wdStory
    With Selection.Find
        .Text = findText
        .Replacement.Text = replaceText
        .Forward = True
        .Wrap = wdFindContinue
    End With
    Selection.Find.Execute Replace:=wdReplaceAll

    ' Replace in headers and footers for each section
    For Each sec In ActiveDocument.Sections
        ' Loop through headers
        For Each hdr In sec.Headers
            If hdr.Exists Then
                Set rng = hdr.Range
                With rng.Find
                    .Text = findText
                    .Replacement.Text = replaceText
                    .Forward = True
                    .Wrap = wdFindContinue
                    .Execute Replace:=wdReplaceAll
                End With
            End If
        Next

        ' Loop through footers
        For Each ftr In sec.Footers
            If ftr.Exists Then
                Set rng = ftr.Range
                With rng.Find
                    .Text = findText
                    .Replacement.Text = replaceText
                    .Forward = True
                    .Wrap = wdFindContinue
                    .Execute Replace:=wdReplaceAll
                End With
            End If
        Next
    Next
   MsgBox EndMsg, vbInformation
End Sub

Run the document and you can enter what you want to find and what you want to replace it with. If you need the finding and replacing to be case sensitive, then add the following to each iteration of the Find and Replace, just before the setting of the .Forward property:

        .MatchCase = True

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (7538) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, Word in Microsoft 365, and 2021.