Printing Graphic Thumbnails

If you work with graphics quite a bit, you are probably already familiar with the term "thumbnails." These are smaller versions of your graphics, printed on a single page, that allow you to get a "birds-eye view" of all your graphics. Many graphics programs and desktop publishing programs include a thumbnail feature that allows you to automatically print your overview. Unfortunately, Word does not include this feature, but you can add such a feature with a macro. The following VBA macro creates a set of thumbnail images from the contents of a single directory:

Sub Thumbnails()
    Dim Directory As String
    Dim FType As String
    Dim FName As String
    Dim ColCount As Integer, J As Integer

    Directory = "d:\temp"
    FType = "*.jpg"

    ChDir Directory
    FName = Dir(FType)
    If FName <> "" Then
        Documents.Add
        ActiveDocument.Tables.Add Range:=Selection.Range, NumRows:=1, _
          NumColumns:=5
        Selection.Tables(1).Select
        Selection.Cells.HeightRule = wdRowHeightAuto
        With Selection.Rows
            .Alignment = wdAlignRowCenter
            .AllowBreakAcrossPages = False
            .SetLeftIndent LeftIndent:=InchesToPoints(0), RulerStyle:= _
              wdAdjustNone
        End With
        Selection.HomeKey Unit:=wdLine
        ColCount = 1
    End If

    Do While FName <> ""
        Selection.InlineShapes.AddPicture FileName:=FName, _
          LinkToFile:=False, SaveWithDocument:=True
        Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
        Selection.TypeParagraph
        With Selection.Font
            .Name = "Arial"
            .Size = 10
            .Bold = True
        End With
         Selection.TypeText Text:=Mid$(FName, Len(Directory) + 2)
        Selection.MoveRight Unit:=wdCharacter, Count:=1
        ColCount = ColCount + 1
        If ColCount = 6 Then
            Selection.InsertRows 1
            Selection.EndKey Unit:=wdLine
            Selection.MoveRight Unit:=wdCharacter, Count:=1
            Selection.InsertRows 1
            Selection.HomeKey Unit:=wdLine
            ColCount = 1
        End If
        FName = Dir
    Loop
End Sub

In this macro, all you need to do is change the line specifying the Directory variable to reflect the directory in which your graphics are stored. You can also change the graphic file specification by changing the assignment of FType (currently it is set to return all JPG files in the directory). When you run this macro, a new document is created, and the macro starts building a table with five columns and however many rows are necessary to print your graphics. The macro will print about 40 or so thumbnails on a piece of paper, depending on the settings you use in your default template.

There is a caveat to using this macro—you should be aware that your document size will grow very, very fast. While the graphics are shown in a small (thumbnail) size in the document, behind the scenes the graphics are maintained at their full size. If you have lots and lots of graphics being processed, then the document size may become unwieldy and you could end up with very sluggish response times from your system.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (8023) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, Word in Microsoft 365, and 2021. You can find a version of this tip for the older menu interface of Word here: Printing Graphic Thumbnails.