Formatting Text Files with VBA

It is not uncommon to need to format text files in Word. For instance, you may get an e-mail message from someone that needs formatting, or you may get an ASCII file from a friend. The most common necessities in formatting such a file is to remove extra spaces or tabs from the beginning of a line, extra spaces or tabs from the end of a line, removing "reply" characters from the beginning of each line, and combining lines to make paragraphs.

Doing all this by hand is time-consuming work and can easily drive you batty, particularly if the file is very large. The following macro should make it easier for you. It accomplishes all the tasks just recounted and does them very quickly.

Sub DoASCII()
    Selection.HomeKey Unit:=wdStory
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "^p^w"
        .Replacement.Text = "^p"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    For J = 1 To 4
        Selection.Find.Text = "^p> "
        Selection.Find.Execute Replace:=wdReplaceAll
    Next J
    Selection.Find.Text = "^p^w"
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.Text = "^w^p"
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.Text = "^p^p"
    Selection.Find.Replacement.Text = "[{}]"
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.Text = "^p"
    Selection.Find.Replacement.Text = " "
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.Text = "[{}]"
    Selection.Find.Replacement.Text = "^p"
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub

You should note that this macro will replace up to four levels of "> " characters put at the beginning of a line. It also assumes that the only place you want paragraph breaks are those places where a blank line exists.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (10895) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Formatting Text Files with VBA.