Accessing a Footnote Number in VBA

Paul is trying to use Word VBA to return the footnote number of the footnote in which the insertion point is located. In his case, it is possible that the footnote contains more than one paragraph. Paul wonders if there is a way to determine this footnote number in VBA.

It is possible to determine a footnote number by using the Index property of a footnote object. Here's a quick way to demonstrate how this info can be useful:

Sub GetFootnoteNumber()
    Dim f As Footnote
    Dim sTemp As String

    sTemp = "The insertion point is not in a footnote"
    For Each f In ActiveDocument.Footnotes
        If Selection.InRange(f.Range) Then
            sTemp = "The insertion point is in footnote " & f.Index
        End If
    Next
    MsgBox sTemp
End Sub

Note that the macro steps through each footnote in the document. If it is determined that the selection (insertion point) is in a particular footnote, then the Index property of that footnote is used to put a message in the sTemp variable. Once done looping through the footnotes, the sTemp variable is displayed in a message box.

If you have a lot of footnotes in your document, you might not want to loop through all of them. In that case, you can use the Information property of the selection to determine if the insertion point is currently in a footnote, in this manner:

Sub GetFootnoteNum()
    Dim J As Integer
    Dim sTemp As String

    sTemp = "The insertion point is not in a footnote"
    If Selection.Information(wdInFootnote) Then
        J = Selection.Paragraphs(1).Range.Footnotes(1).Index
        sTemp = "The insertion point is in footnote " & J
    End If
    MsgBox sTemp
End Sub

In addition, you can derive other information about a particular footnote by expanding what properties of that footnote you access. The following macro returns not only the footnote number, but also the numbering rule, the numbering style, and the starting number for the footnotes:

Sub GetFootnoteInfo()
    Dim f As Footnote
    Dim sTemp As String
    
    sTemp = "The insertion point is not in a footnote"
    If Selection.Information(wdInFootnote) Then
        Set f = Selection.Paragraphs(1).Range.Footnotes(1)
        sTemp = "Footnote number: " & f.Index & vbCr
        With f.Range.FootnoteOptions
            sTemp = sTemp & "Numbering Rule: " & .NumberingRule & vbCr & _
              "Numbering Style: " & .NumberStyle & vbCr & _
              "Starting Number: " & .StartingNumber
        End With
    End If
    MsgBox sTemp
End Sub

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (5906) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, and 2021.