Printing Custom Properties

If you use custom document properties a lot in your documents, you may want a way to print their values. (Custom document properties are like variables for a document. They have many uses in VBA programming.) Unfortunately, there is no command or feature to print them directly. You can, however, copy the properties to a new document, and then print that document.

Basically, all you need to do is to create a new document and then step through all the custom properties in the old document, copying their names and values to the new document. You can do this by making use of the Count property of the CustomDocumentProperties collection, as shown in the following:

Sub PrintDocProps()
    Dim iPropCount As Integer
    Dim i As Integer
    Dim docSource As Document
    Dim docTarget As Document

    Set docSource = ActiveDocument
    Set docTarget = Documents.Add

    docTarget.Activate

    iPropCount = docSource.CustomDocumentProperties.Count

    Selection.TypeText Text:="There are "
    If iPropCount > 0 Then
        Selection.TypeText Text:=iPropCount
    Else
        Selection.TypeText Text:="no"
    End If
    Selection.TypeText Text:=" custom properties in the document."
    Selection.InsertParagraph
    Selection.InsertParagraph

    For i = 1 to iPropCount
        Selection.TypeText _
          Text:=docSource.CustomDocumentProperties(i).Name
        Selection.TypeText Text:="Value: "
        Selection.TypeText _
          Text:=docSource.CustomDocumentProperties(i).Value
        Selection.InsertParagraph
        Selection.InsertParagraph
        Selection.InsertParagraph
    Next i
End Sub

While this code will work just fine, it is not terribly robust. For instance, it does not check to see if there are actually any custom properties in the source document; it just assumes that there are. Such coding could be easily added, however.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (11392) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, and Word in Microsoft 365. You can find a version of this tip for the older menu interface of Word here: Printing Custom Properties.