Removing Spaces before a Note Mark

Kyra routinely uses footnotes and endnotes in the documents on which she works. She has noticed that, at times, there is a space just before the note mark within the main document. Kyra deletes them when she sees them, but she wonders if this is something she can do throughout the entire document, in a single pass.

The short answer is yes; you can. In fact, there are a couple of ways you can approach this task. The first is to use Find and Replace, in this manner:

1. Press Ctrl+H. Word displays the Replace tab of the Find and Replace dialog box.
2. Click the More button, if it is available. (See Figure 1.)



Figure 1. The Replace tab of the Find and Replace dialog box.

3. Make sure the Use Wild Cards radio button is selected.
4. In the Find What box, type a space followed by the following characters: @(^2)
5. Put the following in the Replace With box: \1
6. Click Replace All.

The pattern you use in step 4 is very important. You are telling Word you want to search for any number of spaces followed by a note mark. (That's the ^2 portion of the pattern.) Since the note mark indicator is contained within parentheses, it can be referenced in the Replace With box (step 5).

If you think that there might be tab characters or non-breaking spaces before your note marks, then change the Find What pattern (step 4) to the following:

[ ^s^t]@(^2)

This finds any number of spaces, non-breaking spaces, and tabs—in any combination or order—followed by a note mark. (Note that the opening bracket is followed by a space.)

There is one potential drawback to this approach—it affects note marks in all areas of the document, including the footnotes and endnotes themselves. In most instances this isn't an issue, but Kyra implied that she wanted to only make changes in the main document. If this is the case, then you won't want to click Replace All in step 6. Instead, you'll want to step through the potential changes and only make those that you desire.

If you truly want to affect only the note marks in the main document, then the best way to do that is by using a macro. Here is an approach that relies on a main macro and a helper macro:

Sub RemoveNoteSpaces()
    Dim J As Long

    With ActiveDocument
        For J = .Footnotes.Count To 1 Step -1
            If .Footnotes(J).Reference.StoryType = wdMainTextStory Then
                RemoveSpacesBeforeNote .Footnotes(J).Reference
            End If
        Next J

        For J = .Endnotes.Count To 1 Step -1
            If .Endnotes(J).Reference.StoryType = wdMainTextStory Then
                RemoveSpacesBeforeNote .Endnotes(J).Reference
            End If
        Next J
    End With
End Sub

Private Sub RemoveSpacesBeforeNote(ByVal noteRef As Range)
    Dim startPos As Long
    Dim notePos As Long
    Dim ch As String

    notePos = noteRef.Start
    startPos = notePos

    ' Work backward from the note reference
    Do While startPos > ActiveDocument.Content.Start
        ch = noteRef.Document.Range(Start:=startPos - 1, End:=startPos).Text
        If ch = " " Or ch = ChrW(160) Or ch = vbTab Then
            startPos = startPos - 1
        Else
            Exit Do
        End If
    Loop

    ' Delete unwanted characters
    If startPos < notePos Then
        noteRef.Document.Range(Start:=startPos, End:=notePos).Delete
    End If
End Sub

In the main macro (RemoveNoteSpaces), processing is done from the end of the footnote and endnote collections. This approach within a macro is always a good idea when you are deleting document text. If the footnote or endnote is within the main document (meaning the StoryType is wdMainTextStory), then the helper macro is called.

The helper macro (RemoveSpacesBeforeNote) simply examines characters before the note marker. If the characters are spaces, non-breaking spaces, or tab characters, then they are deleted.

The macro runs very quickly. And, because the main macro only works within the main document, nothing within the footnotes or endnotes themselves are affected.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (14000) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.