Automatically Adding a Word to the AutoCorrect List

Paul notes that, years ago, when you right-clicked on a word that was highlighted as a problematic spelling, the Context menu offered the chance to add the mistyped word to the AutoCorrect list with its correction. That option is gone; now you must add it manually. Paul continues to mistype a few common words, so he wonders if there is a way to automatically add them to his AutoCorrect list.

Microsoft didn't get rid of this capability; they just moved it to a place that is almost impossible to find. (Way to go, Microsoft!) Let's say that one of your common mistypings is "gril" when you really mean "girl." Here's how you can get to the feature previously in the Context menu:

1. When you type "gril" instead of "girl," Word will mark the word as incorrectly spelled.
2. Press F7. Word displays the Editor in a task pane at the right side of the screen and displays the first spelling error it detected.
3. Use the navigation arrows near the top of the Editor task pane to find the "gril" misspelling. The Editor shows possible corrections.
4. Hover the mouse pointer over the correct correction ("girl") and you will see three dots appear to the right of the correction.
5. Click on the three dots to display some further options.
6. Choose Add to AutoCorrect from the options displayed.

This method is nowhere near as convenient as the previous option on the Context menu, and it might as well be nonexistent if you are not familiar with the Editor. Still, it is there and ready to use, if you want to.

Another approach is to use a macro to create the AutoCorrect entry. Here is an example of one that will do the job:

Sub AddToAutoCorrect()
    Dim selectedText As String
    Dim replacementText As String
    Dim acEntry As AutoCorrectEntry
    Dim sTitle As String

    sTitle = "Quick AutoCorrect"

    ' If nothing is selected, use the word at the insertion point
    If Selection.Range.Start = Selection.Range.End Then
        If Selection.Words.Count > 0 Then
            selectedText = Trim(Selection.Words(1).Text)
        End If
    Else
        selectedText = Trim(Selection.Text)
    End If

    ' Get rid of some common punctuation, just in case
    selectedText = Replace(selectedText, ".", "")
    selectedText = Replace(selectedText, ",", "")
    selectedText = Replace(selectedText, ":", "")
    selectedText = Replace(selectedText, ";", "")
    selectedText = Replace(selectedText, "(", "")
    selectedText = Replace(selectedText, ")", "")

    ' Validate we have a word
    If selectedText = "" Then
        MsgBox "Place the insertion point within a word.", vbExclamation, sTitle
        Exit Sub
    End If

    ' Make sure we don't have two (or more) words
    If Instr(selectedText, " ") > 0 Then
        MsgBox "Make sure you only have a single word selected.", _
          vbExclamation, sTitle
        Exit Sub
    End If

    ' Check if entry already exists
    On Error Resume Next
    Set acEntry = AutoCorrect.Entries(selectedText)
    On Error GoTo 0
    If Not acEntry Is Nothing Then
        MsgBox "An AutoCorrect entry for '" & selectedText & _
          "' already exists.", vbInformation, sTitle
        Exit Sub
    End If

    ' Ask for the correction
    replacementText = InputBox("Enter the correct spelling for '" & _
      selectedText & "':", sTitle)

    If replacementText <> "" Then
        AutoCorrect.Entries.Add Name:=selectedText, Value:=replacementText
        MsgBox "Added: " & selectedText & " -> " & replacementText, _
          vbInformation, sTitle
    Else
        MsgBox "You didn't provide a replacement spelling.", vbInformation, _
          sTitle
    End If
End Sub

The macro will take your current selection, ask you what the correct spelling should be, and immediately add it as an AutoCorrect entry—as long as one with the same name doesn't already exist.

If you add the macro to your Quick Access Toolbar, then you have a simple way to add misspelled words to your AutoCorrect entries without the need of utilizing the Editor. You can even assign the macro to a shortcut key.

WordTips is your source for cost-effective Microsoft Word training. (Microsoft Word is the most popular word processing software in the world.) This tip (13978) applies to Microsoft Word 2007, 2010, 2013, 2016, 2019, 2021, 2024, and Word in Microsoft 365.